[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, March 8, 2020 @ 11:52:56
  Author: felixonmars
Revision: 591891

addpkg: haskell-cborg-json 0.2.2.0-1

Added:
  haskell-cborg-json/
  haskell-cborg-json/repos/
  haskell-cborg-json/trunk/
  haskell-cborg-json/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: haskell-cborg-json/trunk/PKGBUILD
===================================================================
--- haskell-cborg-json/trunk/PKGBUILD	                        (rev 0)
+++ haskell-cborg-json/trunk/PKGBUILD	2020-03-08 11:52:56 UTC (rev 591891)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=cborg-json
+pkgname=haskell-cborg-json
+pkgver=0.2.2.0
+pkgrel=1
+pkgdesc="A library for encoding JSON as CBOR"
+url="https://github.com/well-typed/cborg-json"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-cborg' 'haskell-scientific'
+         'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('d42a7af4bf91ddac496c6e7273aebe4c9062504fa10bcdbb17f9ece851daa343aff5d8790113514fd5833513c56fa4a465ee0734adf71a1540af4b8045dd7c93')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname/
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE.txt
+}