[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, March 8, 2020 @ 12:28:27
  Author: felixonmars
Revision: 591937

addpkg: haskell-repline 0.2.2.0-1

Added:
  haskell-repline/
  haskell-repline/repos/
  haskell-repline/trunk/
  haskell-repline/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: haskell-repline/trunk/PKGBUILD
===================================================================
--- haskell-repline/trunk/PKGBUILD	                        (rev 0)
+++ haskell-repline/trunk/PKGBUILD	2020-03-08 12:28:27 UTC (rev 591937)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=repline
+pkgname=haskell-repline
+pkgver=0.2.2.0
+pkgrel=1
+pkgdesc="Haskeline wrapper for GHCi-like REPL interfaces"
+url="https://github.com/sdiehl/repline"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-exceptions')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('7e164d7d4f7ef78057ac6d028d944355ceb944b170f957393228ec14d2bac214ea50ef19f1d3cc88349d3ba010c386871c69452987b0a70e0a47f4e6625414ac')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}