[arch-commits] Commit in haskell-incremental-parser/repos (2 files)

[Felix Yan]

    Date: Sunday, March 8, 2020 @ 15:42:52
  Author: felixonmars
Revision: 592177

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-incremental-parser/repos/community-staging-x86_64/
  haskell-incremental-parser/repos/community-staging-x86_64/PKGBUILD
    (from rev 592176, haskell-incremental-parser/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-incremental-parser/repos/community-staging-x86_64/PKGBUILD (from rev 592176, haskell-incremental-parser/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-08 15:42:52 UTC (rev 592177)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=incremental-parser
+pkgname=haskell-incremental-parser
+pkgver=0.4
+pkgrel=5
+pkgdesc="Generic parser library capable of providing partial results from partial input."
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=('GPL')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-monoid-subclasses' 'haskell-parsers' 'haskell-rank2classes')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-checkers' 'haskell-tasty'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ee02235b3a0ad2828dfcafaf460aeea03b097284354983be8bfeec82a61c8b27aa27e30e3c453a0e0cd8fb77d82fdb2b375b1639c041d16eeb33a2c2de8b793e')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *1.4/<2/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE.txt"
+}