[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, March 8, 2020 @ 18:45:01
  Author: felixonmars
Revision: 592345

addpkg: haskell-tasty-discover 4.2.1-1

Added:
  haskell-tasty-discover/
  haskell-tasty-discover/repos/
  haskell-tasty-discover/trunk/
  haskell-tasty-discover/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: haskell-tasty-discover/trunk/PKGBUILD
===================================================================
--- haskell-tasty-discover/trunk/PKGBUILD	                        (rev 0)
+++ haskell-tasty-discover/trunk/PKGBUILD	2020-03-08 18:45:01 UTC (rev 592345)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=tasty-discover
+pkgname=haskell-tasty-discover
+pkgver=4.2.1
+pkgrel=1
+pkgdesc="Test discovery for the tasty framework"
+url="http://git.coop/lwm/tasty-discover"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-glob')
+makedepends=('ghc' 'haskell-hedgehog' 'haskell-tasty' 'haskell-tasty-hedgehog' 'haskell-tasty-hspec'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck' 'haskell-tasty-smallcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('46dff0398f012d58f53b151ceeea02831149d86d5c4dcc66217c7d53825efadb8dd8226d10d0082ef236763649a39e44c400994a93bd9e7052be7b527f8fa7b7')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    # Hack to allow ghc execute tasty-discover when building tests
+    export PATH="$PWD/dist/build/$_hkgname:$PATH"
+    export LD_LIBRARY_PATH="$PWD/dist/build"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}