[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, March 8, 2020 @ 18:53:07
  Author: felixonmars
Revision: 592351

addpkg: dhall-json 1.6.2-1

Added:
  dhall-json/
  dhall-json/repos/
  dhall-json/trunk/
  dhall-json/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: dhall-json/trunk/PKGBUILD
===================================================================
--- dhall-json/trunk/PKGBUILD	                        (rev 0)
+++ dhall-json/trunk/PKGBUILD	2020-03-08 18:53:07 UTC (rev 592351)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=dhall-json
+pkgver=1.6.2
+pkgrel=1
+pkgdesc='Convert between Dhall and JSON or YAML'
+url='https://dhall-lang.org'
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-aeson-yaml' 'dhall'
+         'haskell-exceptions' 'haskell-optparse-applicative' 'haskell-prettyprinter'
+         'haskell-scientific' 'haskell-unordered-containers' 'haskell-prettyprinter-ansi-terminal')
+makedepends=('ghc' 'haskell-tasty' 'haskell-tasty-hunit')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('69740d975528ac901be0dd58b3307674809c027e9274e9f6f7b4b02a501ee62f8e7cdabf094080cfbb4367994a98a58e7cf4ea59c8afa0c1c97a5349e4429b16')
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgbase}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}