[arch-commits] Commit in haskell-persistent-test/repos (2 files)

[Felix Yan]

    Date: Sunday, March 8, 2020 @ 19:55:54
  Author: felixonmars
Revision: 592442

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent-test/repos/community-staging-x86_64/
  haskell-persistent-test/repos/community-staging-x86_64/PKGBUILD
    (from rev 592441, haskell-persistent-test/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-persistent-test/repos/community-staging-x86_64/PKGBUILD (from rev 592441, haskell-persistent-test/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-08 19:55:54 UTC (rev 592442)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=persistent-test
+pkgname=haskell-persistent-test
+pkgver=2.0.3.0
+pkgrel=96
+pkgdesc="Tests for Persistent"
+url="https://github.com/yesodweb/persistent"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-persistent' 'haskell-persistent-template' 'haskell-aeson'
+         'haskell-blaze-html' 'haskell-conduit' 'haskell-exceptions' 'haskell-hspec'
+         'haskell-hspec-expectations' 'haskell-hunit' 'haskell-monad-control' 'haskell-monad-logger'
+         'haskell-path-pieces' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-random'
+         'haskell-resourcet' 'haskell-transformers-base' 'haskell-unliftio' 'haskell-unliftio-core'
+         'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('511aa72db39687b2b90ef262d5dd83a64887902c2fe57bb87bfd437421170f39af4ebf54ba217eddce80d2afac54ed7e546214775f056e478f20de27c518fdf1')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/TypeFamilies/a \                    StandaloneDeriving\n                    DerivingStrategies\n                    GeneralizedNewtypeDeriving' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver    
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}