[arch-commits] Commit in haskell-casa-client/repos (2 files)

[Felix Yan]

    Date: Sunday, March 8, 2020 @ 22:43:37
  Author: felixonmars
Revision: 592616

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-casa-client/repos/community-staging-x86_64/
  haskell-casa-client/repos/community-staging-x86_64/PKGBUILD
    (from rev 592615, haskell-casa-client/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-casa-client/repos/community-staging-x86_64/PKGBUILD (from rev 592615, haskell-casa-client/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-08 22:43:37 UTC (rev 592616)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=casa-client
+pkgname=haskell-casa-client
+pkgver=0.0.0.20191219
+_commit=3dee7dc1594e4d0ea2b101ad933ce23b4bc3c451
+pkgrel=39
+pkgdesc="Content Addressable Storage Archive client"
+url="https://github.com/fpco/casa"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-base16-bytestring'
+         'haskell-casa-types' 'haskell-conduit' 'haskell-conduit-extra' 'haskell-cryptonite'
+         'haskell-exceptions' 'haskell-http-conduit' 'haskell-http-types' 'haskell-memory'
+         'haskell-network-uri' 'haskell-resourcet' 'haskell-th-lift' 'haskell-unliftio-core'
+         'haskell-unordered-containers')
+makedepends=('ghc')
+source=(casa-$_commit.tar.gz::https://github.com/fpco/casa/archive/$_commit.tar.gz)
+sha512sums=('8f8bd2ffbd250de61aeeafa85c3b3921599aa3fef031966d30581d5abf29bff2f3749350c312d10145331fc054642bf184eabcea69be9baad9be226cb5e4991f')
+
+prepare() {
+    cd casa-$_commit/$_hkgname
+    echo -e "import Distribution.Simple\nmain = defaultMain" > Setup.hs
+}
+
+build() {
+    cd casa-$_commit/$_hkgname
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd casa-$_commit/$_hkgname
+    runhaskell Setup test
+}
+
+package() {
+    cd casa-$_commit/$_hkgname
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "../LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}