[arch-commits] Commit in (5 files)

[Alexander Rødseth]

    Date: Monday, March 9, 2020 @ 14:29:55
  Author: arodseth
Revision: 593108

Add ReactPhysics 3D, a physics engine for C++

Added:
  reactphysics3d/
  reactphysics3d/repos/
  reactphysics3d/repos/community-x86_64/
  reactphysics3d/trunk/
  reactphysics3d/trunk/PKGBUILD

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Added: reactphysics3d/trunk/PKGBUILD
===================================================================
--- reactphysics3d/trunk/PKGBUILD	                        (rev 0)
+++ reactphysics3d/trunk/PKGBUILD	2020-03-09 14:29:55 UTC (rev 593108)
@@ -0,0 +1,53 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+
+pkgbase=reactphysics3d
+pkgname=($pkgbase $pkgbase-docs)
+pkgver=0.7.1
+pkgrel=1
+pkgdesc='Physics engine'
+arch=(x86_64)
+url='https://www.reactphysics3d.com'
+license=(ZLIB)
+makedepends=(cmake ninja)
+source=("https://github.com/DanielChappuis/reactphysics3d/releases/download/v$pkgver/reactphysics3d-$pkgver.tar.gz"
+        "https://www.reactphysics3d.com/documentation/manual/ReactPhysics3D-UserManual.pdf")
+sha256sums=('9e55cc79882120297974b331b81c55fa8e4a6802057e55c3922ed301dd83a20a'
+            '7c6307724bfef92f351150d522fb1a9050400f404e0a3be231946d2b633cb1bd')
+
+prepare() {
+  # Prepare to build a shared library
+  sed -i 's|ADD_LIBRARY(reactphysics3d|ADD_LIBRARY(reactphysics3d SHARED|g' \
+    "$pkgbase-$pkgver/CMakeLists.txt"
+}
+
+build() {
+  mkdir -p build
+  cd build
+  cmake "$srcdir/$pkgbase-$pkgver" \
+    -D CMAKE_CXX_FLAGS="$CXXFLAGS -w" \
+    -D CMAKE_BUILD_TYPE=Release \
+    -D CMAKE_INSTALL_PREFIX=/usr \
+    -D CMAKE_INSTALL_LIBDIR=lib \
+    -D RP3D_DOUBLE_PRECISION_ENABLED="True" \
+    -G Ninja
+  ninja
+}
+
+package_reactphysics3d() {
+  depends=(gcc-libs)
+  DESTDIR="$pkgdir" ninja -C build install
+  install -Dm 644 "$pkgbase-$pkgver/LICENSE" \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_reactphysics3d-docs() {
+  arch=(any)
+  pkgdesc='Pystics engine (user manual)'
+  install -Dm 644 "ReactPhysics3D-UserManual.pdf" \
+    "$pkgdir/usr/share/doc/$pkgname/UserManual.pdf"
+  install -Dm 644 "$pkgbase-$pkgver/LICENSE" \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# getver: github.com/DanielChappuis/reactphysics3d/releases
+# vim: ts=2 sw=2 et: