[arch-commits] Commit in haskell-tasty-hedgehog/repos (2 files)

[Felix Yan]

    Date: Monday, March 9, 2020 @ 23:19:45
  Author: felixonmars
Revision: 593351

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-tasty-hedgehog/repos/community-staging-x86_64/
  haskell-tasty-hedgehog/repos/community-staging-x86_64/PKGBUILD
    (from rev 593350, haskell-tasty-hedgehog/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-tasty-hedgehog/repos/community-staging-x86_64/PKGBUILD (from rev 593350, haskell-tasty-hedgehog/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-09 23:19:45 UTC (rev 593351)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=tasty-hedgehog
+pkgname=haskell-tasty-hedgehog
+pkgver=1.0.0.2
+pkgrel=21
+pkgdesc="Integration for tasty and hedgehog"
+url="https://github.com/qfpl/tasty-hedgehog"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hedgehog' 'haskell-tagged' 'haskell-tasty')
+makedepends=('ghc' 'haskell-tasty-expected-failure')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('56ac4db27b97bc6902633ec398bdbae28f6121d818a29fde62ddea4a4619af0fe7b058b55479414a627119a0014f2c84d6b795c86e9e36d21fd25bf1033a9c4b')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENCE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENCE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENCE"
+}