[arch-commits] Commit in dhall/repos (2 files)

[Felix Yan]

    Date: Tuesday, March 10, 2020 @ 11:43:45
  Author: felixonmars
Revision: 593519

archrelease: copy trunk to community-staging-x86_64

Added:
  dhall/repos/community-staging-x86_64/
  dhall/repos/community-staging-x86_64/PKGBUILD
    (from rev 593518, dhall/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: dhall/repos/community-staging-x86_64/PKGBUILD (from rev 593518, dhall/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-10 11:43:45 UTC (rev 593519)
@@ -0,0 +1,58 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=dhall
+pkgver=1.30.0
+pkgrel=4
+pkgdesc='A configuration language guaranteed to terminate'
+url='https://dhall-lang.org'
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-ansi-terminal'
+         'haskell-atomic-write' 'haskell-case-insensitive' 'haskell-cborg' 'haskell-cborg-json'
+         'haskell-contravariant' 'haskell-data-fix' 'haskell-diff' 'haskell-dotgen'
+         'haskell-either' 'haskell-exceptions' 'haskell-hashable' 'haskell-lens-family-core'
+         'haskell-megaparsec' 'haskell-memory' 'haskell-network-uri' 'haskell-optparse-applicative'
+         'haskell-parsers' 'haskell-parser-combinators' 'haskell-prettyprinter'
+         'haskell-prettyprinter-ansi-terminal' 'haskell-pretty-simple' 'haskell-profunctors'
+         'haskell-repline' 'haskell-serialise' 'haskell-scientific' 'haskell-th-lift-instances'
+         'haskell-transformers-compat' 'haskell-unordered-containers' 'haskell-uri-encode'
+         'haskell-vector' 'haskell-cryptonite' 'haskell-http-types' 'haskell-http-client'
+         'haskell-http-client-tls')
+makedepends=('ghc' 'haskell-foldl' 'haskell-generic-random' 'haskell-mockery' 'haskell-quickcheck'
+             'haskell-quickcheck-instances' 'haskell-special-values' 'haskell-spoon'
+             'haskell-tasty' 'haskell-tasty-expected-failure' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck' 'haskell-turtle' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('31a3001e7c6cd652d7a9fdb3eb1a78c461e177498df1a19e1fd0782821708f7d0b41d46468ea9120b8e36b935486a6fe3b724713ad17a818198cc5bcb7d5a46c')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -i -e 's/< *2.1/<3/' -e '/semigroups/d' $pkgname.cabal
+}
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgbase}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}