[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, March 11, 2020 @ 14:17:18
  Author: felixonmars
Revision: 594238

addpkg: haskell-rope-utf16-splay 0.3.1.0-1

Added:
  haskell-rope-utf16-splay/
  haskell-rope-utf16-splay/repos/
  haskell-rope-utf16-splay/trunk/
  haskell-rope-utf16-splay/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: haskell-rope-utf16-splay/trunk/PKGBUILD
===================================================================
--- haskell-rope-utf16-splay/trunk/PKGBUILD	                        (rev 0)
+++ haskell-rope-utf16-splay/trunk/PKGBUILD	2020-03-11 14:17:18 UTC (rev 594238)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=rope-utf16-splay
+pkgname=haskell-rope-utf16-splay
+pkgver=0.3.1.0
+pkgrel=1
+pkgdesc="Ropes optimised for updating using UTF-16 code units and row/column pairs"
+url="https://github.com/ollef/rope-utf16-splay"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('2ec20f8acaec58dd181f6d82379111fc882f9029db5caa1f157713338eb9cae297d8eb395d5966e4a0c1fc31ad9b8b9b5539192654343c81562bbdd545da49ad')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}