[arch-commits] Commit in haskell-hasql-pool/repos (2 files)

[Felix Yan]

    Date: Thursday, March 12, 2020 @ 00:53:57
  Author: felixonmars
Revision: 594844

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hasql-pool/repos/community-staging-x86_64/
  haskell-hasql-pool/repos/community-staging-x86_64/PKGBUILD
    (from rev 594843, haskell-hasql-pool/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: haskell-hasql-pool/repos/community-staging-x86_64/PKGBUILD (from rev 594843, haskell-hasql-pool/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-12 00:53:57 UTC (rev 594844)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=hasql-pool
+pkgname=haskell-hasql-pool
+pkgver=0.5.1
+pkgrel=68
+pkgdesc="A pool of connections for Hasql"
+url="https://github.com/nikita-volkov/hasql-pool"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-prelude' 'haskell-hasql' 'haskell-resource-pool')
+makedepends=('ghc' 'haskell-hspec')
+checkdepends=('pifpaf' 'postgresql')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('09f25a26f2317a0cdfa578ddb0ab23f6077c3e2849da2d4ecb72f2e1c63a57693b566269a2a01b5fb2bca8a3c85871ee6c24be715e9c9b810001447cee1c4a3e')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/5432/9824/' test/Main.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --disable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+
+    eval $(pifpaf run postgresql --host 127.0.0.1)
+    createuser -s postgres
+    #runhaskell Setup test
+    pifpaf_stop
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}