[arch-commits] Commit in haskell-vty/repos (2 files)

[Felix Yan]

    Date: Friday, March 13, 2020 @ 08:30:36
  Author: felixonmars
Revision: 595668

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-vty/repos/community-staging-x86_64/
  haskell-vty/repos/community-staging-x86_64/PKGBUILD
    (from rev 595667, haskell-vty/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-vty/repos/community-staging-x86_64/PKGBUILD (from rev 595667, haskell-vty/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-13 08:30:36 UTC (rev 595668)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=vty
+pkgname=haskell-vty
+pkgver=5.28.1
+pkgrel=1
+pkgdesc="A simple terminal UI library"
+url="https://github.com/jtdaugherty/vty"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-blaze-builder' 'haskell-microlens'
+         'haskell-microlens-mtl' 'haskell-microlens-th' 'haskell-hashable' 'haskell-parallel'
+         'haskell-utf8-string' 'haskell-vector')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-smallcheck'
+             'haskell-quickcheck-assertions' 'haskell-test-framework'
+             'haskell-test-framework-smallcheck' 'haskell-test-framework-hunit' 'haskell-random'
+             'haskell-string-qq')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ba178f3cb4a36e5c9957ae1aea1aabe6f941a08ceb2527eb18fb07a0a7d59f0773abb71aec28286f09a19436f3f02d91fdcf59331f63d2d9cda37f5eb5d6b436')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    # https://github.com/jtdaugherty/vty/issues/132
+    # https://github.com/haskell/cabal/issues/4918
+    cd $_hkgname-$pkgver
+    # runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}