[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, March 13, 2020 @ 12:45:22
  Author: felixonmars
Revision: 595921

addpkg: haskell-quickcheck-classes-base 0.6.0.0-1

Added:
  haskell-quickcheck-classes-base/
  haskell-quickcheck-classes-base/repos/
  haskell-quickcheck-classes-base/trunk/
  haskell-quickcheck-classes-base/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: haskell-quickcheck-classes-base/trunk/PKGBUILD
===================================================================
--- haskell-quickcheck-classes-base/trunk/PKGBUILD	                        (rev 0)
+++ haskell-quickcheck-classes-base/trunk/PKGBUILD	2020-03-13 12:45:22 UTC (rev 595921)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=quickcheck-classes-base
+pkgname=haskell-quickcheck-classes-base
+pkgver=0.6.0.0
+pkgrel=1
+pkgdesc="QuickCheck common typeclasses from 'base'"
+url="https://github.com/andrewthad/quickcheck-classes-base"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-orphans' 'haskell-bifunctors' 'haskell-contravariant'
+         'haskell-quickcheck' 'haskell-tagged')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('3d0a7c68ab1cdaddbd272df633e0704f5ee3997b3a86fe79cb960f7c84f8546f3360b9d52ada45b9db6344135f0aab1093d5304935ae19f43d235790fba83216')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e '/fail$/d' -e '/semigroups/d' $_hkgname.cabal
+    echo -e "import Distribution.Simple\nmain = defaultMain" > Setup.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}