[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, March 13, 2020 @ 22:11:53
  Author: felixonmars
Revision: 596313

addpkg: haskell-deriving-compat 0.5.8-1

Added:
  haskell-deriving-compat/
  haskell-deriving-compat/repos/
  haskell-deriving-compat/trunk/
  haskell-deriving-compat/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: haskell-deriving-compat/trunk/PKGBUILD
===================================================================
--- haskell-deriving-compat/trunk/PKGBUILD	                        (rev 0)
+++ haskell-deriving-compat/trunk/PKGBUILD	2020-03-13 22:11:53 UTC (rev 596313)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=deriving-compat
+pkgname=haskell-deriving-compat
+pkgver=0.5.8
+pkgrel=1
+pkgdesc="Backports of GHC deriving extensions"
+url="https://github.com/haskell-compat/deriving-compat"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-th-abstraction' 'haskell-transformers-compat')
+makedepends=('ghc' 'haskell-base-compat' 'haskell-base-orphans' 'haskell-hspec' 'haskell-quickcheck'
+             'haskell-tagged')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('e0a807142bc324a0205bd3b98fc9c68292100808d448edaf800ed41c073ec0745329458dbbb6c1fe33cc86872a9d2555d76f57c6b9d8a1dcd891dda1a9fcf158')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}