[arch-commits] Commit in gst-plugins-good/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Friday, March 13, 2020 @ 23:58:29
  Author: heftig
Revision: 377518

archrelease: copy trunk to extra-x86_64

Added:
  gst-plugins-good/repos/extra-x86_64/PKGBUILD
    (from rev 377517, gst-plugins-good/trunk/PKGBUILD)
Deleted:
  gst-plugins-good/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  120 +++++++++++++++++++++++++++++++++++++------------------------
 1 file changed, 73 insertions(+), 47 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-03-13 23:57:12 UTC (rev 377517)
+++ PKGBUILD	2020-03-13 23:58:29 UTC (rev 377518)
@@ -1,47 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Maintainer: Jan de Groot <jgc at archlinux.org>
-
-pkgname=gst-plugins-good
-pkgver=1.16.2
-pkgrel=2
-pkgdesc="GStreamer open-source multimedia framework good plugins"
-url="https://gstreamer.freedesktop.org/"
-arch=(x86_64)
-license=(LGPL)
-depends=(libpulse libsoup gst-plugins-base-libs wavpack aalib taglib libdv libshout libvpx
-         gdk-pixbuf2 libcaca libavc1394 libiec61883 libxdamage v4l-utils cairo libgudev speex flac
-         libraw1394 lame mpg123 twolame gtk3 qt5-declarative qt5-x11extras qt5-wayland)
-makedepends=(python gtk-doc git meson jack2)
-checkdepends=(gst-plugins-base)
-_commit=ce0723527aa37d5f4d19ef8021c0b2eb8f83b08d  # tags/1.16.2^0
-source=("git+https://gitlab.freedesktop.org/gstreamer/gst-plugins-good.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-}
-
-build() {
-  arch-meson $pkgname build \
-    -D gobject-cast-checks=disabled \
-    -D glib-asserts=disabled \
-    -D glib-checks=disabled \
-    -D package-name="GStreamer Good Plugins (Arch Linux)" \
-    -D package-origin="https://www.archlinux.org/"
-  ninja -C build
-}
-
-check() {
-  meson test -C build --print-errorlogs
-}
-
-package() {
-  depends+=(libjack.so)
-
-  DESTDIR="$pkgdir" meson install -C build
-}

Copied: gst-plugins-good/repos/extra-x86_64/PKGBUILD (from rev 377517, gst-plugins-good/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-03-13 23:58:29 UTC (rev 377518)
@@ -0,0 +1,73 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gst-plugins-good
+pkgname=(gst-plugins-good gst-plugin-gtk gst-plugin-qmlgl)
+pkgver=1.16.2
+pkgrel=3
+pkgdesc="GStreamer open-source multimedia framework good plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(libpulse libsoup gst-plugins-base-libs wavpack aalib taglib libdv libshout libvpx
+         gdk-pixbuf2 libcaca libavc1394 libiec61883 libxdamage v4l-utils cairo libgudev speex flac
+         libraw1394 lame mpg123 twolame)
+makedepends=(python gtk-doc git meson jack2 gtk3 qt5-{declarative,x11extras,wayland})
+checkdepends=(gst-plugins-base xorg-server-xvfb)
+options=(!emptydirs)
+_commit=ce0723527aa37d5f4d19ef8021c0b2eb8f83b08d  # tags/1.16.2^0
+source=("git+https://gitlab.freedesktop.org/gstreamer/gst-plugins-good.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D gobject-cast-checks=disabled \
+    -D glib-asserts=disabled \
+    -D glib-checks=disabled \
+    -D package-name="GStreamer Good Plugins (Arch Linux)" \
+    -D package-origin="https://www.archlinux.org/"
+  ninja -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  export XDG_RUNTIME_DIR
+
+  xvfb-run -s '-screen 0 1920x1080x24 -nolisten local +iglx -noreset' \
+    meson test -C build --print-errorlogs
+)
+
+package_gst-plugins-good() {
+  depends+=(libjack.so)
+
+  DESTDIR="$pkgdir" meson install -C build
+
+  for _x in gtk qmlgl; do
+    mkdir -p "$_x/lib/gstreamer-1.0"
+    _f="lib/gstreamer-1.0/libgst${_x}.so"
+    mv "$pkgdir/usr/$_f" "$_x/$_f"
+  done
+}
+
+package_gst-plugin-gtk() {
+  pkgdesc="GStreamer open-source multimedia framework gtk plugin"
+  depends=(gst-plugins-base-libs gtk3)
+
+  mv gtk "$pkgdir/usr"
+}
+
+package_gst-plugin-qmlgl() {
+  pkgdesc="GStreamer open-source multimedia framework qmlgl plugin"
+  depends=(gst-plugins-base-libs qt5-{declarative,x11extras,wayland})
+
+  mv qmlgl "$pkgdir/usr"
+}