[arch-commits] Commit in (4 files)

[David Runge]

    Date: Saturday, March 14, 2020 @ 22:09:15
  Author: dvzrv
Revision: 597359

Adding python-pytest-verbose-parametrize as checkdepends for molecule.

Added:
  python-pytest-verbose-parametrize/
  python-pytest-verbose-parametrize/repos/
  python-pytest-verbose-parametrize/trunk/
  python-pytest-verbose-parametrize/trunk/PKGBUILD

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Added: python-pytest-verbose-parametrize/trunk/PKGBUILD
===================================================================
--- python-pytest-verbose-parametrize/trunk/PKGBUILD	                        (rev 0)
+++ python-pytest-verbose-parametrize/trunk/PKGBUILD	2020-03-14 22:09:15 UTC (rev 597359)
@@ -0,0 +1,40 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=pytest-verbose-parametrize
+pkgname=python-pytest-verbose-parametrize
+pkgver=1.7.0
+pkgrel=1
+pkgdesc="Pytest parametrize hook to generate ids for parametrized tests"
+arch=('any')
+url="https://github.com/man-group/pytest-plugins/tree/master/pytest-verbose-parametrize"
+license=('MIT')
+depends=('python-pytest' 'python-six')
+makedepends=('python-setuptools')
+checkdepends=('python-coverage' 'python-mock' 'python-pytest-virtualenv')
+source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
+sha512sums=('ac81cdf002d60b4af916c4beb4c832c9c39dc9dcfa3eea7385b093f9ea18391cbf968a4e908abdb23523a7cb1e294dce2017083414e61eef6762f157319e2cf4')
+
+prepare() {
+  mv -v "${_name}-${pkgver}" "$pkgname-$pkgver"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  python setup.py build
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  export PYTHONPATH="build:${PYTHONPATH}"
+  pytest -v -k 'not test_handles_apparent_duplicates and not test_truncates_long_ids'
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  python setup.py install --skip-build \
+    --optimize=1 \
+    --prefix=/usr \
+    --root="${pkgdir}"
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -vDm 644 {CHANGES,README}.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+}