[arch-commits] Commit in gnome-shell/repos (3 files)

[Jan Steffens]

    Date: Sunday, March 15, 2020 @ 02:24:04
  Author: heftig
Revision: 377549

archrelease: copy trunk to testing-x86_64

Added:
  gnome-shell/repos/testing-x86_64/
  gnome-shell/repos/testing-x86_64/PKGBUILD
    (from rev 377548, gnome-shell/trunk/PKGBUILD)
  gnome-shell/repos/testing-x86_64/gnome-shell.install
    (from rev 377548, gnome-shell/trunk/gnome-shell.install)

---------------------+
 PKGBUILD            |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 gnome-shell.install |    7 +++++++
 2 files changed, 56 insertions(+)

Copied: gnome-shell/repos/testing-x86_64/PKGBUILD (from rev 377548, gnome-shell/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-03-15 02:24:04 UTC (rev 377549)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Flamelab <panosfilip at gmail.com
+
+pkgname=gnome-shell
+pkgver=3.36.0+35+gd9a75412c
+pkgrel=1
+epoch=1
+pkgdesc="Next generation desktop shell"
+url="https://wiki.gnome.org/Projects/GnomeShell"
+arch=(x86_64)
+license=(GPL2)
+depends=(accountsservice gcr gjs gnome-bluetooth upower gnome-session gnome-settings-daemon
+         gnome-themes-extra gsettings-desktop-schemas libcanberra-pulse libgdm libsecret
+         mutter nm-connection-editor unzip gstreamer libibus gnome-autoar)
+makedepends=(gtk-doc gnome-control-center evolution-data-server gobject-introspection git meson
+             sassc asciidoc)
+optdepends=('gnome-control-center: System settings'
+            'evolution-data-server: Evolution calendar integration')
+groups=(gnome)
+install=gnome-shell.install
+_commit=d9a75412c3e843890588a1e794f3014ee65e5619  # master
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+  
+build() {
+  arch-meson $pkgname build -D gtk_doc=true
+  ninja -C build
+}
+
+package() {
+  depends+=(libmutter-6.so)
+  DESTDIR="$pkgdir" meson install -C build
+}

Copied: gnome-shell/repos/testing-x86_64/gnome-shell.install (from rev 377548, gnome-shell/trunk/gnome-shell.install)
===================================================================
--- testing-x86_64/gnome-shell.install	                        (rev 0)
+++ testing-x86_64/gnome-shell.install	2020-03-15 02:24:04 UTC (rev 377549)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/gnome-shell
+}
+
+post_upgrade() {
+  post_install
+}