[arch-commits] Commit in haskell-http-types/repos (2 files)

[Felix Yan]

    Date: Sunday, March 15, 2020 @ 20:10:53
  Author: felixonmars
Revision: 598486

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-types/repos/community-staging-x86_64/
  haskell-http-types/repos/community-staging-x86_64/PKGBUILD
    (from rev 598485, haskell-http-types/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-http-types/repos/community-staging-x86_64/PKGBUILD (from rev 598485, haskell-http-types/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-15 20:10:53 UTC (rev 598486)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Nagy <danielnagy at gmx de>
+
+_hkgname=http-types
+pkgname=haskell-http-types
+pkgver=0.12.3
+pkgrel=49
+pkgdesc="Generic HTTP types for Haskell (for both client and server code)."
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-case-insensitive')
+makedepends=('ghc' 'haskell-doctest' 'haskell-hspec' 'haskell-quickcheck'
+             'haskell-quickcheck-instances')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('fdaf95cfd29ed47445af4ad6349fcbbf4dcd8341f3963da453f8be5eccae4757904d3c4e7a8719ab576a7e7857aaa035ecfc1aa8f99f4ec6fce950c7ccc76597')
+
+build() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid -fnetwork-uri
+    runhaskell Setup build
+    runhaskell Setup register   --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}