[arch-commits] Commit in haskell-rerebase/repos (2 files)

[Felix Yan]

    Date: Sunday, March 15, 2020 @ 21:51:56
  Author: felixonmars
Revision: 598654

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-rerebase/repos/community-staging-x86_64/
  haskell-rerebase/repos/community-staging-x86_64/PKGBUILD
    (from rev 598653, haskell-rerebase/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-rerebase/repos/community-staging-x86_64/PKGBUILD (from rev 598653, haskell-rerebase/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-15 21:51:56 UTC (rev 598654)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=rerebase
+pkgname=haskell-rerebase
+pkgver=1.6
+pkgrel=4
+pkgdesc='Reexports from "base" with a bunch of other standard libraries'
+url="https://github.com/nikita-volkov/rerebase"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-rebase')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('79d28249e071c7dc20637ee777c793c35274f66594d5b18299c3382507dc18c9b65becec8444fbbafb3344e172d4acf5c6ad8a41a80b4810e141a72dcd832214')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/==1/>=1/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}