[arch-commits] Commit in sopel/repos (2 files)

[Felix Yan]

    Date: Thursday, March 19, 2020 @ 17:34:44
  Author: felixonmars
Revision: 600987

archrelease: copy trunk to community-testing-any

Added:
  sopel/repos/community-testing-any/
  sopel/repos/community-testing-any/PKGBUILD
    (from rev 600986, sopel/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: sopel/repos/community-testing-any/PKGBUILD (from rev 600986, sopel/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2020-03-19 17:34:44 UTC (rev 600987)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=sopel
+pkgver=7.0.0
+pkgrel=1
+pkgdesc="An easy-to-use and highly extensible IRC Bot framework (Formerly Willie)"
+arch=('any')
+license=('custom:EFL')
+url='https://sopel.chat'
+depends=('python-setuptools' 'sqlite' 'python-xmltodict' 'python-pytz' 'python-praw'
+         'python-geoip2' 'python-requests' 'python-dnspython' 'python-sqlalchemy')
+makedepends=('python-sphinx' 'python-sphinxcontrib-autoprogram')
+checkdepends=('python-pytest-runner')
+backup=('etc/sopel.cfg')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/sopel-irc/sopel/archive/v$pkgver.tar.gz")
+sha512sums=('d6745ee71527848fe782be9a939e61847315583eb46347fa67e48f7a9acbda30164f43282243485bbdd4e81969688aed60f611136b00aa797dc7b05bb95e85b6')
+
+prepare() {
+  cd sopel-$pkgver
+  sed -i -e 's/<3/<4/' -e 's/<6/<7/' {dev-,}requirements.txt
+}
+
+build() {
+  cd sopel-$pkgver
+  python setup.py build egg_info
+  PYTHONPATH="$PWD" make -C docs man
+}
+
+check() {
+  cd sopel-$pkgver
+  python setup.py pytest --addopts "--ignore build/"
+}
+
+package() {
+  cd sopel-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm644 contrib/sopel.cfg "$pkgdir/etc/sopel.cfg"
+  install -Dm644 contrib/sopel.service "$pkgdir/usr/lib/systemd/system/sopel.service"
+  install -Dm644 contrib/sopel.conf "$pkgdir/usr/lib/tmpfiles.d/sopel.conf"
+  install -Dm644 docs/build/man/sopel.1 "$pkgdir/usr/share/man/man1/sopel.1"
+}