[arch-commits] Commit in haskell-hledger-lib/repos (2 files)

[Felix Yan]

    Date: Friday, March 20, 2020 @ 16:05:09
  Author: felixonmars
Revision: 601898

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hledger-lib/repos/community-staging-x86_64/
  haskell-hledger-lib/repos/community-staging-x86_64/PKGBUILD
    (from rev 601897, haskell-hledger-lib/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-hledger-lib/repos/community-staging-x86_64/PKGBUILD (from rev 601897, haskell-hledger-lib/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-20 16:05:09 UTC (rev 601898)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hledger-lib
+pkgname=haskell-hledger-lib
+pkgver=1.17.1
+pkgrel=1
+pkgdesc="Core data types, parsers and functionality for the hledger accounting tools"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-base-compat-batteries'
+         'haskell-blaze-markup' 'haskell-call-stack' 'haskell-cassava' 'haskell-cassava-megaparsec'
+         'haskell-cmdargs' 'haskell-data-default' 'haskell-decimal' 'haskell-extra' 'haskell-fgl'
+         'haskell-file-embed' 'haskell-glob' 'haskell-hashtables' 'haskell-megaparsec'
+         'haskell-old-time' 'haskell-parser-combinators' 'haskell-pretty-show' 'haskell-regex-tdfa'
+         'haskell-safe' 'haskell-split' 'haskell-tabular' 'haskell-tasty' 'haskell-tasty-hunit'
+         'haskell-timeit' 'haskell-uglymemo' 'haskell-utf8-string')
+makedepends=('ghc' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('04563c51783155d42968881021a2e027491d380282425c7e7f34d58a24fb5e719e3f5e5e295d8a6e9f9011f9532d6905a2eaf87701edc4257a3f019b4682cdd0')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}