[arch-commits] Commit in haskell-trifecta/repos (2 files)

[Felix Yan]

    Date: Saturday, March 21, 2020 @ 07:45:14
  Author: felixonmars
Revision: 602402

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-trifecta/repos/community-staging-x86_64/
  haskell-trifecta/repos/community-staging-x86_64/PKGBUILD
    (from rev 602401, haskell-trifecta/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-trifecta/repos/community-staging-x86_64/PKGBUILD (from rev 602401, haskell-trifecta/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-21 07:45:14 UTC (rev 602402)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=trifecta
+pkgname=haskell-trifecta
+pkgver=2.1
+pkgrel=30
+pkgdesc="A modern parser combinator library with convenient diagnostics"
+url="https://github.com/ekmett/trifecta/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-ansi-terminal" "haskell-blaze-builder" "haskell-blaze-html"
+         "haskell-blaze-markup" "haskell-charset" "haskell-comonad" "haskell-fingertree"
+         "haskell-hashable" "haskell-lens" "haskell-parsers" 'haskell-prettyprinter'
+         'haskell-prettyprinter-ansi-terminal' "haskell-profunctors" "haskell-reducers"
+         "haskell-unordered-containers" "haskell-utf8-string")
+makedepends=('ghc' 'haskell-cabal-doctest' 'haskell-doctest' 'haskell-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('0929ee4a3d9a53c211b13a711814b4b6ea488ad40f373befdc7e8a479b2a95c4e97a19381873af54d377ff2af49782677fa2ea892ea69522c242e245debd3a25')
+
+prepare() {
+    sed -i -e '/semigroups/d' $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}