[arch-commits] Commit in haskell-servant-swagger/repos (2 files)

[Felix Yan]

    Date: Saturday, March 21, 2020 @ 08:30:02
  Author: felixonmars
Revision: 602466

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-servant-swagger/repos/community-staging-x86_64/
  haskell-servant-swagger/repos/community-staging-x86_64/PKGBUILD
    (from rev 602465, haskell-servant-swagger/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-servant-swagger/repos/community-staging-x86_64/PKGBUILD (from rev 602465, haskell-servant-swagger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-21 08:30:02 UTC (rev 602466)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=servant-swagger
+pkgname=haskell-servant-swagger
+pkgver=1.1.8
+pkgrel=11
+pkgdesc="Generate Swagger specification for your servant API."
+url="https://github.com/haskell-servant/servant-swagger"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-http-media'
+         'haskell-insert-ordered-containers' 'haskell-lens' 'haskell-servant'
+         'haskell-singleton-bool' 'haskell-swagger2' 'haskell-unordered-containers'
+         'haskell-hspec' 'haskell-quickcheck')
+makedepends=('ghc' 'haskell-base-compat' 'haskell-cabal-doctest' 'haskell-doctest'
+             'haskell-hspec-discover' 'haskell-lens-aeson' 'haskell-utf8-string' 'haskell-vector')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('7ddf92df0ef594ab08ef247cd953b55933ec2fba489678a9dee139345b80ffd40e40285d7cf0775d468b5de5c883cc6ba430208949cc406b150c573ed7e7b74a')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *4.19/<5/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test || warning "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}