[arch-commits] Commit in link/repos/community-x86_64 (5 files)
David Runge
dvzrv at archlinux.org
Sat Mar 21 20:17:08 UTC 2020
Date: Saturday, March 21, 2020 @ 20:17:07
Author: dvzrv
Revision: 603099
archrelease: copy trunk to community-x86_64
Added:
link/repos/community-x86_64/PKGBUILD
(from rev 603098, link/trunk/PKGBUILD)
link/repos/community-x86_64/link-3.0.2-cmake_system_paths.patch
(from rev 603098, link/trunk/link-3.0.2-cmake_system_paths.patch)
link/repos/community-x86_64/link-3.0.2-use_system_libs.patch
(from rev 603098, link/trunk/link-3.0.2-use_system_libs.patch)
Deleted:
link/repos/community-x86_64/PKGBUILD
link/repos/community-x86_64/link-devendor-asio.patch
-------------------------------------+
PKGBUILD | 131 +++++++++++++++++++---------------
link-3.0.2-cmake_system_paths.patch | 19 ++++
link-3.0.2-use_system_libs.patch | 27 +++++++
link-devendor-asio.patch | 16 ----
4 files changed, 120 insertions(+), 73 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2020-03-21 20:17:00 UTC (rev 603098)
+++ PKGBUILD 2020-03-21 20:17:07 UTC (rev 603099)
@@ -1,57 +0,0 @@
-# Maintainer: David Runge <dave at sleepmap.de>
-pkgname=link
-pkgver=3.0.2
-pkgrel=1
-pkgdesc="Synchronizes musical beat, tempo, and phase across multiple applications"
-arch=('x86_64')
-url="https://github.com/ableton/link"
-license=('GPL2')
-depends=('asio')
-makedepends=('cmake' 'portaudio' 'qt5-tools' 'qt5-quickcontrols')
-optdepends=('jack: for JACK examples'
- 'portaudio: for portaudio based examples'
- 'qt5-quickcontrols: for Qt examples')
-source=("$pkgname-$pkgver.tar.gz::https://github.com/Ableton/link/archive/Link-${pkgver}.tar.gz"
- "${pkgname}-devendor-asio.patch")
-sha512sums=('7ee81721272fe758f59889bd5c3cef4fae14189fda7113b46f71128d5ca2bed280dc2271a23ec522d49cd21653ae9999f1b58aa8c68b50e323e0dfa46d15c95e'
- '41b474ed14b6a72a637fdd796c11bda42aaceed342a2b9ab4dcce8724414e2f3e36a30b57484cf4e22493926f1e1b5eb3b818dd710efcc5cb996c6abe58a4230')
-
-prepare() {
- mv -v "${pkgname}-Link-${pkgver}" "$pkgname-$pkgver"
- cd "$pkgname-$pkgver"
- patch -Np1 -i "../${pkgname}-devendor-asio.patch"
- mkdir -v build
-}
-
-build() {
- cd "$pkgname-$pkgver/build"
- cmake \
- -DCMAKE_INSTALL_PREFIX=/usr \
- -DLINK_BUILD_JACK=ON \
- -DLINK_BUILD_QT_EXAMPLES=ON \
- ..
- make
-}
-
-check() {
- cd "$pkgname-$pkgver/build"
- bin/LinkCoreTest
- bin/LinkDiscoveryTest
-}
-
-package() {
- local dirs=('discovery' 'discovery/test' 'discovery/v1' 'link' 'link/v1'
- 'platforms' 'platforms/asio' 'platforms/darwin' 'platforms/linux'
- 'platforms/posix' 'platforms/stl' 'platforms/windows' 'test' 'test/serial_io'
- 'util' 'util/test')
- cd "$pkgname-$pkgver/build"
- install -vDm 644 ../include/ableton/*.{ipp,hpp} \
- -t "${pkgdir}/usr/include/ableton"
- for dir in "${dirs[@]}"; do
- install -vDm 644 ../include/ableton/"${dir}"/*.hpp \
- -t "${pkgdir}/usr/include/ableton/${dir}"
- done
- install -vDm 755 bin/{LinkHut,QLinkHut,QLinkHutSilent} -t "${pkgdir}/usr/bin/"
- install -vDm 644 ../{{README,CONTRIBUTING}.md,*.pdf} \
- -t "${pkgdir}/usr/share/doc/${pkgname}/"
-}
Copied: link/repos/community-x86_64/PKGBUILD (from rev 603098, link/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2020-03-21 20:17:07 UTC (rev 603099)
@@ -0,0 +1,74 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgname=link
+pkgver=3.0.2
+pkgrel=2
+pkgdesc="Synchronizes musical beat, tempo, and phase across multiple applications"
+arch=('x86_64')
+url="https://github.com/ableton/link"
+license=('GPL2')
+depends=('asio')
+makedepends=('catch2' 'cmake' 'portaudio' 'qt5-tools' 'qt5-quickcontrols')
+optdepends=('jack: for JACK examples'
+ 'portaudio: for portaudio based examples'
+ 'qt5-quickcontrols: for Qt examples')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/Ableton/link/archive/Link-${pkgver}.tar.gz"
+ "${pkgname}-3.0.2-cmake_system_paths.patch"
+ "${pkgname}-3.0.2-use_system_libs.patch")
+sha512sums=('7ee81721272fe758f59889bd5c3cef4fae14189fda7113b46f71128d5ca2bed280dc2271a23ec522d49cd21653ae9999f1b58aa8c68b50e323e0dfa46d15c95e'
+ '8ccd3cc531b64fc91d1b5ba8c1de2a0f6aa52399e1ad5b971cf68b503aa471accb71834e8157b9c4b7a86a346d882f5408e7b99ba890a0baaf2cef21545424e9'
+ '4683948b7bdc42f85674ad7ebed4abe8123a95580c0892a9c326d05e4783c2e875254e7d9c98767b5c8cc11b85023d31533f4535ffcf9654736a72abe256e6ca')
+
+prepare() {
+ mv -v "${pkgname}-Link-${pkgver}" "$pkgname-$pkgver"
+ cd "$pkgname-$pkgver"
+ # using system libraries when integrating
+ patch -Np1 -i "../${pkgname}-3.0.2-use_system_libs.patch"
+ # the cmake integration is used to build tests and examples, so duplicating
+ # before patching
+ cp -v AbletonLinkConfig.cmake{,.local}
+ patch -Np1 -i "../${pkgname}-3.0.2-cmake_system_paths.patch"
+ mv -v AbletonLinkConfig.cmake{,.system}
+ mv -v AbletonLinkConfig.cmake{.local,}
+}
+
+build() {
+ cd "$pkgname-$pkgver"
+ # fixing the catch2 include for the test binaries
+ export CXXFLAGS+=" -I/usr/include/catch2"
+ cmake -DCMAKE_INSTALL_PREFIX=/usr \
+ -DLINK_BUILD_JACK=ON \
+ -DLINK_BUILD_QT_EXAMPLES=ON \
+ -B build \
+ -S .
+ make -C build
+}
+
+check() {
+ cd "$pkgname-$pkgver/build"
+ bin/LinkCoreTest
+ bin/LinkDiscoveryTest
+}
+
+package() {
+ local dirs=('discovery' 'discovery/test' 'discovery/v1' 'link' 'link/v1'
+ 'platforms' 'platforms/asio' 'platforms/darwin' 'platforms/linux'
+ 'platforms/posix' 'platforms/stl' 'platforms/windows' 'test' 'test/serial_io'
+ 'util' 'util/test')
+ cd "$pkgname-$pkgver"
+ install -vDm 644 include/ableton/*.{ipp,hpp} \
+ -t "${pkgdir}/usr/include/ableton"
+ for dir in "${dirs[@]}"; do
+ install -vDm 644 include/ableton/"${dir}"/*.hpp \
+ -t "${pkgdir}/usr/include/ableton/${dir}"
+ done
+ # install cmake integration
+ install -vDm 644 AbletonLinkConfig.cmake.system \
+ "${pkgdir}/usr/lib/cmake/link/AbletonLinkConfig.cmake"
+ install -vDm 644 cmake_include/AsioStandaloneConfig.cmake \
+ -t "${pkgdir}/usr/lib/cmake/link/cmake_include"
+ # examples
+ install -vDm 755 build/bin/{LinkHut,QLinkHut,QLinkHutSilent} -t "${pkgdir}/usr/bin/"
+ install -vDm 644 {{README,CONTRIBUTING}.md,*.pdf} \
+ -t "${pkgdir}/usr/share/doc/${pkgname}/"
+}
Copied: link/repos/community-x86_64/link-3.0.2-cmake_system_paths.patch (from rev 603098, link/trunk/link-3.0.2-cmake_system_paths.patch)
===================================================================
--- link-3.0.2-cmake_system_paths.patch (rev 0)
+++ link-3.0.2-cmake_system_paths.patch 2020-03-21 20:17:07 UTC (rev 603099)
@@ -0,0 +1,19 @@
+diff -ruN a/AbletonLinkConfig.cmake b/AbletonLinkConfig.cmake
+--- a/AbletonLinkConfig.cmake 2018-05-29 12:37:09.000000000 +0200
++++ b/AbletonLinkConfig.cmake 2020-03-21 20:19:34.040771008 +0100
+@@ -5,7 +5,7 @@
+ add_library(Ableton::Link IMPORTED INTERFACE)
+ set_property(TARGET Ableton::Link APPEND PROPERTY
+ INTERFACE_INCLUDE_DIRECTORIES
+- ${CMAKE_CURRENT_LIST_DIR}/include
++ ${CMAKE_CURRENT_LIST_DIR}/../../../include
+ )
+
+ # Force C++11 support for consuming targets
+@@ -50,5 +50,5 @@
+
+ set_property(TARGET Ableton::Link APPEND PROPERTY
+ INTERFACE_SOURCES
+- ${CMAKE_CURRENT_LIST_DIR}/include/ableton/Link.hpp
++ ${CMAKE_CURRENT_LIST_DIR}/../../../include/ableton/Link.hpp
+ )
Copied: link/repos/community-x86_64/link-3.0.2-use_system_libs.patch (from rev 603098, link/trunk/link-3.0.2-use_system_libs.patch)
===================================================================
--- link-3.0.2-use_system_libs.patch (rev 0)
+++ link-3.0.2-use_system_libs.patch 2020-03-21 20:17:07 UTC (rev 603099)
@@ -0,0 +1,27 @@
+Description: Drop dependencies on included 3rd-party libs
+ upstream includes git-submodules for Catch and ASIO (not found in the tarball).
+ on Debian we want to use the system provided libraries.
+Author: IOhannes m zmölnig
+Origin: Debian
+Forwarded: not-needed
+Last-Update: 2016-10-26
+---
+This patch header follows DEP-3: http://dep.debian.net/deps/dep3/
+--- ableton-link.orig/cmake_include/AsioStandaloneConfig.cmake
++++ ableton-link/cmake_include/AsioStandaloneConfig.cmake
+@@ -1,6 +1,2 @@
+ add_library(AsioStandalone::AsioStandalone IMPORTED INTERFACE)
+
+-set_property(TARGET AsioStandalone::AsioStandalone APPEND PROPERTY
+- INTERFACE_INCLUDE_DIRECTORIES
+- ${CMAKE_CURRENT_LIST_DIR}/../modules/asio-standalone/asio/include
+-)
+--- ableton-link.orig/cmake_include/CatchConfig.cmake
++++ ableton-link/cmake_include/CatchConfig.cmake
+@@ -1,6 +1,2 @@
+ add_library(Catch::Catch IMPORTED INTERFACE)
+
+-set_property(TARGET Catch::Catch APPEND PROPERTY
+- INTERFACE_INCLUDE_DIRECTORIES
+- ${CMAKE_SOURCE_DIR}/third_party/catch
+-)
Deleted: link-devendor-asio.patch
===================================================================
--- link-devendor-asio.patch 2020-03-21 20:17:00 UTC (rev 603098)
+++ link-devendor-asio.patch 2020-03-21 20:17:07 UTC (rev 603099)
@@ -1,16 +0,0 @@
-diff -ruN a/AbletonLinkConfig.cmake b/AbletonLinkConfig.cmake
---- a/AbletonLinkConfig.cmake 2018-05-29 12:37:09.000000000 +0200
-+++ b/AbletonLinkConfig.cmake 2019-03-14 16:26:10.468519266 +0100
-@@ -42,12 +42,6 @@
- )
- endif()
-
--include(${CMAKE_CURRENT_LIST_DIR}/cmake_include/AsioStandaloneConfig.cmake)
--set_property(TARGET Ableton::Link APPEND PROPERTY
-- INTERFACE_LINK_LIBRARIES
-- AsioStandalone::AsioStandalone
--)
--
- set_property(TARGET Ableton::Link APPEND PROPERTY
- INTERFACE_SOURCES
- ${CMAKE_CURRENT_LIST_DIR}/include/ableton/Link.hpp
More information about the arch-commits
mailing list