[arch-commits] Commit in haskell-storable-record/repos (2 files)

[Felix Yan]

    Date: Sunday, March 22, 2020 @ 01:55:22
  Author: felixonmars
Revision: 603339

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-storable-record/repos/community-staging-x86_64/
  haskell-storable-record/repos/community-staging-x86_64/PKGBUILD
    (from rev 603338, haskell-storable-record/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-storable-record/repos/community-staging-x86_64/PKGBUILD (from rev 603338, haskell-storable-record/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-22 01:55:22 UTC (rev 603339)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=storable-record
+pkgname=haskell-storable-record
+pkgver=0.0.4.1
+pkgrel=3
+pkgdesc="Elegant definition of Storable instances for records"
+url="http://code.haskell.org/~thielema/storable-record/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-utility-ht')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b263cf8a4c9dc5d4fb1dccb773bb47eca15bf19704e046184bc6c4c697c91900c92d2c78faf9b661e2e58bc101db3a7799e5ce2580cb74c69006bef158c9c026')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fsplitbase -f-buildtests
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}