[arch-commits] Commit in bat/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Alexander Rødseth]

    Date: Sunday, March 22, 2020 @ 18:40:38
  Author: arodseth
Revision: 603595

archrelease: copy trunk to community-x86_64

Added:
  bat/repos/community-x86_64/PKGBUILD
    (from rev 603594, bat/trunk/PKGBUILD)
Deleted:
  bat/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   77 ++++++++++++++++++++++++++++++++++---------------------------
 1 file changed, 43 insertions(+), 34 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-03-22 18:40:32 UTC (rev 603594)
+++ PKGBUILD	2020-03-22 18:40:38 UTC (rev 603595)
@@ -1,34 +0,0 @@
-# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
-# Contributor: Wesley Moore <wes at wezm.net>
-
-pkgname=bat
-pkgver=0.12.1
-pkgrel=1
-pkgdesc='Cat clone with syntax highlighting and git integration'
-arch=(x86_64)
-url='https://github.com/sharkdp/bat'
-license=(APACHE MIT)
-makedepends=(cmake rust clang)
-depends=(libssh2)
-source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
-sha256sums=('1dd184ddc9e5228ba94d19afc0b8b440bfc1819fef8133fe331e2c0ec9e3f8e2')
-
-build() {
-  cd "$pkgname-$pkgver"
-
-  cargo build --release
-}
-
-package() {
-  cd "$pkgname-$pkgver"
-
-  install -Dm755 target/release/$pkgname "$pkgdir/usr/bin/$pkgname"
-  install -Dm644 doc/bat.1 "$pkgdir/usr/share/man/man1/bat.1"
-  install -Dm644 LICENSE-APACHE \
-    "$pkgdir/usr/share/licenses/$pkgname/LICENSE-APACHE"
-  install -Dm644 LICENSE-MIT \
-    "$pkgdir/usr/share/licenses/$pkgname/LICENSE-MIT"
-}
-
-# getver: github.com/sharkdp/bat/releases/latest
-# vim: ts=2 sw=2 et:

Copied: bat/repos/community-x86_64/PKGBUILD (from rev 603594, bat/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-03-22 18:40:38 UTC (rev 603595)
@@ -0,0 +1,43 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Wesley Moore <wes at wezm.net>
+
+pkgname=bat
+pkgver=0.13.0
+pkgrel=1
+pkgdesc='Cat clone with syntax highlighting and git integration'
+arch=(x86_64)
+url='https://github.com/sharkdp/bat'
+license=(APACHE MIT)
+makedepends=(clang cmake git rust)
+depends=(libssh2)
+source=("git+$url#commit=5edd8260e8fef887bd4c7e39c411dfe843d03894") # tag: v0.13.0
+sha256sums=('SKIP')
+
+build() {
+  cd $pkgname
+  cargo build --release
+}
+
+package() {
+  cd $pkgname
+
+  # Package the executable
+  install -Dm755 target/release/$pkgname "$pkgdir/usr/bin/$pkgname"
+
+  # Package the license files
+  install -Dm644 LICENSE-APACHE \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE-APACHE"
+  install -Dm644 LICENSE-MIT \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE-MIT"
+
+  # Package the man page
+  find "$srcdir" -name bat.1 -exec install -Dm644 {} \
+    "$pkgdir/usr/share/man/man1/bat.1" \;
+
+  # Package the fish completion file
+  find "$srcdir" -name fish-complete -exec install -Dm644 {} \
+    "$pkgdir/usr/local/share/fish/vendor_completions.d/fish-complete" \;
+}
+
+# getver: github.com/sharkdp/bat/releases/latest
+# vim: ts=2 sw=2 et: