[arch-commits] Commit in electron7/repos (9 files)
Jonas Witschel
diabonas at archlinux.org
Wed Mar 25 12:07:06 UTC 2020
Date: Wednesday, March 25, 2020 @ 12:07:06
Author: diabonas
Revision: 604061
archrelease: copy trunk to community-testing-x86_64
Added:
electron7/repos/community-testing-x86_64/
electron7/repos/community-testing-x86_64/PKGBUILD
(from rev 604060, electron7/trunk/PKGBUILD)
electron7/repos/community-testing-x86_64/chromium-skia-harmony.patch
(from rev 604060, electron7/trunk/chromium-skia-harmony.patch)
electron7/repos/community-testing-x86_64/chromium-system-icu.patch
(from rev 604060, electron7/trunk/chromium-system-icu.patch)
electron7/repos/community-testing-x86_64/chromium-system-zlib.patch
(from rev 604060, electron7/trunk/chromium-system-zlib.patch)
electron7/repos/community-testing-x86_64/default_app-icon.patch
(from rev 604060, electron7/trunk/default_app-icon.patch)
electron7/repos/community-testing-x86_64/electron7.desktop
(from rev 604060, electron7/trunk/electron7.desktop)
electron7/repos/community-testing-x86_64/icu65.patch
(from rev 604060, electron7/trunk/icu65.patch)
electron7/repos/community-testing-x86_64/use-system-libraries-in-node.patch
(from rev 604060, electron7/trunk/use-system-libraries-in-node.patch)
------------------------------------+
PKGBUILD | 200 +++++++++++++++++++++++++++++++++++
chromium-skia-harmony.patch | 14 ++
chromium-system-icu.patch | 20 +++
chromium-system-zlib.patch | 13 ++
default_app-icon.patch | 21 +++
electron7.desktop | 7 +
icu65.patch | 64 +++++++++++
use-system-libraries-in-node.patch | 56 +++++++++
8 files changed, 395 insertions(+)
Copied: electron7/repos/community-testing-x86_64/PKGBUILD (from rev 604060, electron7/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2020-03-25 12:07:06 UTC (rev 604061)
@@ -0,0 +1,200 @@
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
+# Contributor: Nicola Squartini <tensor5 at gmail.com>
+
+pkgname=electron7
+pkgver=7.1.14
+_commit=0f082ecd5c378a36b5b9bd6d150a00d5dc34da6c
+_chromiumver=78.0.3904.130
+pkgrel=2
+pkgdesc='Build cross platform desktop apps with web technologies'
+arch=('x86_64')
+url='https://electronjs.org/'
+license=('MIT' 'custom')
+depends=('c-ares' 'ffmpeg' 'gtk3' 'http-parser' 'libevent' 'libnghttp2'
+ 'libxslt' 'libxss' 'minizip' 'nss' 're2' 'snappy')
+makedepends=('clang' 'git' 'gn' 'gperf' 'harfbuzz-icu' 'java-runtime-headless'
+ 'jsoncpp' 'libnotify' 'lld' 'llvm' 'ninja' 'npm' 'pciutils' 'yarn'
+ 'python2' 'wget' 'yasm')
+optdepends=('kde-cli-tools: file deletion support (kioclient5)'
+ 'libappindicator-gtk3: StatusNotifierItem support'
+ 'trash-cli: file deletion support (trash-put)'
+ "xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)")
+source=('git+https://github.com/electron/electron.git'
+ 'git+https://chromium.googlesource.com/chromium/tools/depot_tools.git'
+ "$pkgname.desktop"
+ 'default_app-icon.patch'
+ 'use-system-libraries-in-node.patch'
+ 'icu65.patch'
+ 'chromium-skia-harmony.patch'
+ 'chromium-system-icu.patch'
+ 'chromium-system-zlib.patch')
+sha512sums=('SKIP'
+ 'SKIP'
+ 'f2384d851478507b8b76ada5822d021b0ab86e6cb7d078294171cf43935f3362f383b8399fa29acd11f021df5f43c3a0337b173702313c4533946bb36b7e512d'
+ '8c7fb91a3e5f0ba9e031d4011c5167b872e54751a64f78816f66376a5ac8af81e59e3fb6301140056f61ced44903acb3acbd106ad5d5f6503e7566bc6b7ee5b9'
+ '147563fe422108598af26c617edf78d146d4e70223e3093216d5f63a1ab051eff95abd0c8f8c0b6f8a504ae26557d65cd0ffd90c542d6534176b72b99ea44a5e'
+ 'd109937c4a5fba96e82d6fbc7b804943010d5723eef91af4f79355c8b84214da3978fc784dd0fcc3ed228c4684d0d06cf8cd21fa32fc5ec80c00d1bb4e3b9c90'
+ '6fa7c5f737b3f86274b1f768aadf863dd7542fca9c8885d5c3804590bd04c288394c54b2003234be37d961f48b5470ce15254ba64b2716f8aceb181e1fd3c7c0'
+ '7413e0cca7102008dd5bee443dcde90be69ef1d0973fee576f70544f0d0a66aa8bc7099e619c89160915d6cd6186384be46ffab4a1d747000133dda9a84e15e5'
+ '89d62431e11cf8f3b48afdf9a133a8532916d445676de12acb48b0aaca3aa45106e25de399e7ee37a6220b0766c0ea65f10da219d4bb9a7a02275b4364e493ad')
+
+_system_libs=('ffmpeg'
+ 'flac'
+ 'fontconfig'
+ 'freetype'
+ 'harfbuzz-ng'
+ 'icu'
+ 'libdrm'
+ 'libevent'
+ 'libjpeg'
+# 'libpng'
+# 'libvpx'
+ 'libwebp'
+ 'libxml'
+ 'libxslt'
+# 'openh264'
+ 'opus'
+ 're2'
+ 'snappy'
+ 'yasm'
+ 'zlib')
+
+prepare() {
+ mkdir -p "$srcdir"/python2-path
+ ln -sf /usr/bin/python2 "$srcdir"/python2-path/python
+ export PATH="$srcdir/python2-path:$PATH:$srcdir/depot_tools"
+
+ echo 'Fetching chromium...'
+ git clone --branch=$_chromiumver --depth=1 https://chromium.googlesource.com/chromium/src.git
+
+ echo "solutions = [
+ {
+ \"name\": \"src/electron\",
+ \"url\": \"file://$srcdir/electron@$_commit\",
+ \"deps_file\": \"DEPS\",
+ \"managed\": False,
+ \"custom_deps\": {
+ \"src\": None,
+ },
+ \"custom_vars\": {},
+ },
+]" > .gclient
+
+ python2 "$srcdir"/depot_tools/gclient.py sync \
+ --with_branch_heads \
+ --with_tags \
+ --nohooks
+
+ sed -e "s/'am'/'apply'/" -i src/electron/script/lib/git.py
+
+ echo 'Running hooks...'
+ # python2 "$srcdir"/depot_tools/gclient.py runhooks
+ python2 src/build/landmines.py
+ python2 src/build/util/lastchange.py -o src/build/util/LASTCHANGE
+ python2 src/build/util/lastchange.py -m GPU_LISTS_VERSION \
+ --revision-id-only --header src/gpu/config/gpu_lists_version.h
+ python2 src/build/util/lastchange.py -m SKIA_COMMIT_HASH \
+ -s src/third_party/skia --header src/skia/ext/skia_commit_hash.h
+ # Create sysmlink to system Node.js
+ mkdir -p src/third_party/node/linux/node-linux-x64/bin
+ ln -sf /usr/bin/node src/third_party/node/linux/node-linux-x64/bin
+ python2 src/third_party/depot_tools/download_from_google_storage.py \
+ --no_resume --extract --no_auth --bucket chromium-nodejs \
+ -s src/third_party/node/node_modules.tar.gz.sha1
+ vpython src/tools/download_cros_provided_profile.py \
+ --newest_state=src/chrome/android/profiles/newest.txt \
+ --local_state=src/chrome/android/profiles/local.txt \
+ --output_name=src/chrome/android/profiles/afdo.prof \
+ --gs_url_base=chromeos-prebuilt/afdo-job/llvm
+ python2 src/electron/script/apply_all_patches.py \
+ src/electron/patches/config.json
+ cd src/electron
+ yarn install --frozen-lockfile
+ cd ..
+
+ echo 'Patching Chromium for using system libraries...'
+ sed -i 's/OFFICIAL_BUILD/GOOGLE_CHROME_BUILD/' \
+ tools/generate_shim_headers/generate_shim_headers.py
+ for lib in "${_system_libs[@]}" libjpeg_turbo; do
+ third_party_dir=third_party/"$lib"
+ if [ ! -d "$third_party_dir" ]; then
+ third_party_dir=base/"$third_party_dir"
+ fi
+ find "$third_party_dir" -type f \
+ \! -path "$third_party_dir/chromium/*" \
+ \! -path "$third_party_dir/google/*" \
+ \! -path 'third_party/yasm/run_yasm.py' \
+ \! -regex '.*\.\(gn\|gni\|isolate\)' \
+ -delete
+ done
+ python2 build/linux/unbundle/replace_gn_files.py \
+ --system-libraries \
+ "${_system_libs[@]}"
+
+ echo 'Applying local patches...'
+ patch -Np0 -i ../chromium-skia-harmony.patch
+ patch -Np1 -i ../icu65.patch
+ patch -Np1 -i ../chromium-system-icu.patch
+ patch -Np1 -i ../chromium-system-zlib.patch
+ patch -Np1 -i ../use-system-libraries-in-node.patch
+ patch -Np1 -i ../default_app-icon.patch # Icon from .desktop file
+}
+
+build() {
+ export CC=clang
+ export CXX=clang++
+ export AR=ar
+ export NM=nm
+
+ # Do not warn about unknown warning options
+ CFLAGS+=' -Wno-unknown-warning-option'
+ CXXFLAGS+=' -Wno-unknown-warning-option'
+
+ cd src
+ export CHROMIUM_BUILDTOOLS_PATH="$PWD"/buildtools
+ GN_EXTRA_ARGS='
+ blink_symbol_level = 0
+ clang_use_chrome_plugins = false
+ custom_toolchain = "//build/toolchain/linux/unbundle:default"
+ host_toolchain = "//build/toolchain/linux/unbundle:default"
+ icu_use_data_file = false
+ is_component_ffmpeg = false
+ link_pulseaudio = true
+ linux_use_bundled_binutils = false
+ treat_warnings_as_errors = false
+ use_custom_libcxx = false
+ use_gnome_keyring = false
+ use_sysroot = false
+ '
+ gn gen out/Release \
+ --args="import(\"//electron/build/args/release.gn\") $GN_EXTRA_ARGS"
+ ninja -C out/Release electron
+ # Strip before zip to avoid
+ # zipfile.LargeZipFile: Filesize would require ZIP64 extensions
+ strip -s out/Release/electron
+ ninja -C out/Release electron_dist_zip
+ # ninja -C out/Release third_party/electron_node:headers
+}
+
+package() {
+ install -dm755 "$pkgdir"/usr/lib/$pkgname
+ bsdtar -xf src/out/Release/dist.zip -C "$pkgdir"/usr/lib/$pkgname
+
+ chmod u+s "$pkgdir"/usr/lib/$pkgname/chrome-sandbox
+
+ install -dm755 "$pkgdir"/usr/share/licenses/$pkgname
+ for l in "$pkgdir"/usr/lib/$pkgname/{LICENSE,LICENSES.chromium.html}; do
+ ln -s \
+ $(realpath --relative-to="$pkgdir"/usr/share/licenses/$pkgname $l) \
+ "$pkgdir"/usr/share/licenses/$pkgname
+ done
+
+ install -dm755 "$pkgdir"/usr/bin
+ ln -s ../lib/$pkgname/electron "$pkgdir"/usr/bin/$pkgname
+
+ # Install .desktop and icon file (see default_app-icon.patch)
+ install -Dm644 -t "$pkgdir"/usr/share/applications $pkgname.desktop
+ install -Dm644 src/electron/default_app/icon.png \
+ "$pkgdir"/usr/share/pixmaps/$pkgname.png # hicolor has no 1024x1024
+}
+
Copied: electron7/repos/community-testing-x86_64/chromium-skia-harmony.patch (from rev 604060, electron7/trunk/chromium-skia-harmony.patch)
===================================================================
--- community-testing-x86_64/chromium-skia-harmony.patch (rev 0)
+++ community-testing-x86_64/chromium-skia-harmony.patch 2020-03-25 12:07:06 UTC (rev 604061)
@@ -0,0 +1,14 @@
+--- third_party/skia/src/ports/SkFontHost_FreeType.cpp.orig 2019-07-19 11:08:34.770972665 +0000
++++ third_party/skia/src/ports/SkFontHost_FreeType.cpp 2019-07-19 11:08:44.274442065 +0000
+@@ -128,9 +128,9 @@ public:
+ : fGetVarDesignCoordinates(nullptr)
+ , fGetVarAxisFlags(nullptr)
+ , fLibrary(nullptr)
+- , fIsLCDSupported(false)
++ , fIsLCDSupported(true)
+ , fLightHintingIsYOnly(false)
+- , fLCDExtra(0)
++ , fLCDExtra(2)
+ {
+ if (FT_New_Library(&gFTMemory, &fLibrary)) {
+ return;
Copied: electron7/repos/community-testing-x86_64/chromium-system-icu.patch (from rev 604060, electron7/trunk/chromium-system-icu.patch)
===================================================================
--- community-testing-x86_64/chromium-system-icu.patch (rev 0)
+++ community-testing-x86_64/chromium-system-icu.patch 2020-03-25 12:07:06 UTC (rev 604061)
@@ -0,0 +1,20 @@
+diff --git a/build/linux/unbundle/icu.gn b/build/linux/unbundle/icu.gn
+index 4450e40..9ca36dd 100644
+--- a/build/linux/unbundle/icu.gn
++++ b/build/linux/unbundle/icu.gn
+@@ -96,6 +96,7 @@ shim_headers("icui18n_shim") {
+ "unicode/fpositer.h",
+ "unicode/gender.h",
+ "unicode/gregocal.h",
++ "unicode/listformatter.h",
+ "unicode/measfmt.h",
+ "unicode/measunit.h",
+ "unicode/measure.h",
+@@ -178,7 +179,6 @@ shim_headers("icuuc_shim") {
+ "unicode/icudataver.h",
+ "unicode/icuplug.h",
+ "unicode/idna.h",
+- "unicode/listformatter.h",
+ "unicode/localpointer.h",
+ "unicode/locdspnm.h",
+ "unicode/locid.h",
Copied: electron7/repos/community-testing-x86_64/chromium-system-zlib.patch (from rev 604060, electron7/trunk/chromium-system-zlib.patch)
===================================================================
--- community-testing-x86_64/chromium-system-zlib.patch (rev 0)
+++ community-testing-x86_64/chromium-system-zlib.patch 2020-03-25 12:07:06 UTC (rev 604061)
@@ -0,0 +1,13 @@
+diff --git a/third_party/perfetto/gn/BUILD.gn b/third_party/perfetto/gn/BUILD.gn
+index 3bc618a..e0ddf6d 100644
+--- a/third_party/perfetto/gn/BUILD.gn
++++ b/third_party/perfetto/gn/BUILD.gn
+@@ -244,7 +244,7 @@ if (enable_perfetto_trace_processor || perfetto_build_standalone ||
+ "//buildtools:zlib",
+ ]
+ } else {
+- public_configs = [ "//third_party/zlib:zlib_config" ]
++ public_configs = [ "//third_party/zlib:system_zlib" ]
+ public_deps = [
+ "//third_party/zlib",
+ ]
Copied: electron7/repos/community-testing-x86_64/default_app-icon.patch (from rev 604060, electron7/trunk/default_app-icon.patch)
===================================================================
--- community-testing-x86_64/default_app-icon.patch (rev 0)
+++ community-testing-x86_64/default_app-icon.patch 2020-03-25 12:07:06 UTC (rev 604061)
@@ -0,0 +1,21 @@
+/electron/default_app/default_app.ts
++++ b/electron/default_app/default_app.ts
+@@ -60,7 +60,7 @@
+ }
+
+ if (process.platform === 'linux') {
+- options.icon = path.join(__dirname, 'icon.png')
++ options.icon = '/usr/share/pixmaps/electron.png'
+ }
+
+ mainWindow = new BrowserWindow(options)
+--- a/electron/filenames.gni
++++ b/electron/filenames.gni
+@@ -6,7 +6,6 @@
+ ]
+
+ default_app_static_sources = [
+- "default_app/icon.png",
+ "default_app/index.html",
+ "default_app/package.json",
+ "default_app/styles.css",
Copied: electron7/repos/community-testing-x86_64/electron7.desktop (from rev 604060, electron7/trunk/electron7.desktop)
===================================================================
--- community-testing-x86_64/electron7.desktop (rev 0)
+++ community-testing-x86_64/electron7.desktop 2020-03-25 12:07:06 UTC (rev 604061)
@@ -0,0 +1,7 @@
+[Desktop Entry]
+Type=Application
+Name=Electron
+Icon=electron6
+Exec=electron6 %u
+Categories=Development;GTK;
+StartupNotify=true
Copied: electron7/repos/community-testing-x86_64/icu65.patch (from rev 604060, electron7/trunk/icu65.patch)
===================================================================
--- community-testing-x86_64/icu65.patch (rev 0)
+++ community-testing-x86_64/icu65.patch 2020-03-25 12:07:06 UTC (rev 604061)
@@ -0,0 +1,64 @@
+From 5679c3c191ed62b62d8db22f1657a296ee9bfe8e Mon Sep 17 00:00:00 2001
+From: Frank Tang <ftang at chromium.org>
+Date: Wed, 30 Oct 2019 22:49:47 +0000
+Subject: [PATCH] Update ICU to 65.1 from 64 and fix broken tests
+
+ICU 65-1 release note
+http://site.icu-project.org/download/65
+
+CLDR 36 release blog
+http://blog.unicode.org/2019/10/unicode-cldr-version-36-languagelocale.html
+
+Most of the test expectation change is due to CLDR 36 update
+of Grapheme Cluster for Indic languages
+See the following for related changes in ICU 65.1 in this area:
+https://unicode-org.atlassian.net/browse/CLDR-10994
+https://unicode-org.atlassian.net/browse/ICU-13637
+https://github.com/unicode-org/cldr/blob/master/common/properties/segments/readme.txt
+
+Bug: chromium:1014272, chromium:1017047
+Change-Id: I9fc6d4620bf2a4c189940d06d8c79893502db3dd
+Cq-Include-Trybots: luci.chromium.try:linux_layout_tests_layout_ng_disabled
+Reviewed-on: https://chromium-review.googlesource.com/c/chromium/src/+/1866059
+Reviewed-by: Jungshik Shin <jshin at chromium.org>
+Reviewed-by: Doug Turner <dougt at chromium.org>
+Reviewed-by: Michael Wasserman <msw at chromium.org>
+Reviewed-by: Kent Tamura <tkent at chromium.org>
+Reviewed-by: Trent Apted <tapted at chromium.org>
+Reviewed-by: Mason Freed <masonfreed at chromium.org>
+Commit-Queue: Frank Tang <ftang at chromium.org>
+Cr-Commit-Position: refs/heads/master@{#711027}
+---
+ third_party/blink/renderer/core/dom/document.cc | 2 +-
+ ui/gfx/render_text_harfbuzz.cc | 5 ++++-
+ 2 files changed, 5 insertions(+), 2 deletions(-)
+
+diff --git a/third_party/blink/renderer/core/dom/document.cc b/third_party/blink/renderer/core/dom/document.cc
+index 511aac29086..f188cf548a6 100644
+--- a/third_party/blink/renderer/core/dom/document.cc
++++ b/third_party/blink/renderer/core/dom/document.cc
+@@ -6191,7 +6191,7 @@ static ParseQualifiedNameResult ParseQualifiedNameInternal(
+
+ for (unsigned i = 0; i < length;) {
+ UChar32 c;
+- U16_NEXT(characters, i, length, c)
++ U16_NEXT(characters, i, length, c);
+ if (c == ':') {
+ if (saw_colon)
+ return ParseQualifiedNameResult(kQNMultipleColons);
+diff --git a/ui/gfx/render_text_harfbuzz.cc b/ui/gfx/render_text_harfbuzz.cc
+index 50e86af6b97..0339ff3ff8e 100644
+--- a/ui/gfx/render_text_harfbuzz.cc
++++ b/ui/gfx/render_text_harfbuzz.cc
+@@ -971,7 +971,10 @@ RangeF TextRunHarfBuzz::GetGraphemeBounds(RenderTextHarfBuzz* render_text,
+ ++total;
+ }
+ }
+- DCHECK_GT(total, 0);
++ // With ICU 65.1, DCHECK_GT() below fails.
++ // See https://crbug.com/1017047 for more details.
++ //
++ // DCHECK_GT(total, 0);
+
+ // It's possible for |text_index| to point to a diacritical mark, at the end
+ // of |chars|. In this case all the grapheme boundaries come before it. Just
Copied: electron7/repos/community-testing-x86_64/use-system-libraries-in-node.patch (from rev 604060, electron7/trunk/use-system-libraries-in-node.patch)
===================================================================
--- community-testing-x86_64/use-system-libraries-in-node.patch (rev 0)
+++ community-testing-x86_64/use-system-libraries-in-node.patch 2020-03-25 12:07:06 UTC (rev 604061)
@@ -0,0 +1,56 @@
+--- a/third_party/electron_node/BUILD.gn
++++ b/third_party/electron_node/BUILD.gn
+@@ -42,6 +42,18 @@
+ node_module_version = ""
+ }
+
++if (is_linux) {
++ import("//build/config/linux/pkg_config.gni")
++
++ pkg_config("cares") {
++ packages = [ "libcares" ]
++ }
++
++ pkg_config("nghttp2") {
++ packages = [ "libnghttp2" ]
++ }
++}
++
+ assert(!node_use_dtrace, "node_use_dtrace not supported in GN")
+ assert(!node_use_etw, "node_use_etw not supported in GN")
+
+@@ -203,12 +215,8 @@
+ component("node_lib") {
+ deps = [
+ ":node_js2c",
+- "deps/cares",
+ "deps/histogram",
+- "deps/http_parser",
+ "deps/llhttp",
+- "deps/nghttp2",
+- "deps/zlib",
+ "//third_party/brotli:dec",
+ "//third_party/brotli:enc",
+ "//v8:v8_libplatform",
+@@ -222,6 +230,21 @@
+ public_configs = [ ":node_lib_config" ]
+ include_dirs = [ "src" ]
+ libs = []
++ if (is_linux) {
++ configs += [
++ ":cares",
++ ":nghttp2",
++ ]
++ deps += [ "//third_party/zlib" ]
++ libs += [ "http_parser" ]
++ } else {
++ deps += [
++ "deps/cares",
++ "deps/http_parser",
++ "deps/nghttp2",
++ "deps/zlib",
++ ]
++ }
+ cflags_cc = [
+ "-Wno-deprecated-declarations",
+ "-Wno-implicit-fallthrough",
More information about the arch-commits
mailing list