[arch-commits] Commit in gnome-remote-desktop/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Wednesday, March 25, 2020 @ 23:15:40
  Author: heftig
Revision: 378500

archrelease: copy trunk to extra-x86_64

Added:
  gnome-remote-desktop/repos/extra-x86_64/PKGBUILD
    (from rev 378499, gnome-remote-desktop/trunk/PKGBUILD)
Deleted:
  gnome-remote-desktop/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   85 ++++++++++++++++++++++++++++++++++---------------------------
 1 file changed, 48 insertions(+), 37 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-03-25 23:14:32 UTC (rev 378499)
+++ PKGBUILD	2020-03-25 23:15:40 UTC (rev 378500)
@@ -1,37 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-
-pkgname=gnome-remote-desktop
-pkgver=0.1.7
-pkgrel=2
-pkgdesc="GNOME Remote Desktop server"
-url="https://wiki.gnome.org/Projects/Mutter/RemoteDesktop"
-arch=(x86_64)
-license=(GPL2)
-depends=(glib2 libpipewire02 systemd libvncserver libsecret libnotify dconf)
-makedepends=(git meson)
-groups=(gnome)
-_commit=400f790f082dc54bf03d27cf64fcf94b0a1424c9  # tags/0.1.7^0
-source=("git+https://gitlab.gnome.org/jadahl/gnome-remote-desktop.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-}
-
-build() {
-  arch-meson $pkgname build
-  ninja -C build
-}
-
-check() {
-  meson test -C build
-}
-
-package() {
-  DESTDIR="$pkgdir" meson install -C build
-}

Copied: gnome-remote-desktop/repos/extra-x86_64/PKGBUILD (from rev 378499, gnome-remote-desktop/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-03-25 23:15:40 UTC (rev 378500)
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-remote-desktop
+pkgver=0.1.8
+pkgrel=1
+pkgdesc="GNOME Remote Desktop server"
+url="https://wiki.gnome.org/Projects/Mutter/RemoteDesktop"
+arch=(x86_64)
+license=(GPL2)
+depends=(glib2 pipewire systemd libvncserver libsecret libnotify dconf)
+makedepends=(git meson)
+checkdepends=(xorg-server-xvfb python-dbus python-gobject mutter)
+groups=(gnome)
+_commit=3141a7efec1529f06e2bcc64b68d8bad02d9a4c1  # tags/0.1.8^0
+source=("git+https://gitlab.gnome.org/jadahl/gnome-remote-desktop.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # Disable the Xvfb abstract socket which leaks out of our containers
+  sed -i 's|-noreset|& -nolisten local|' tests/vnc-test-runner.sh
+}
+
+build() {
+  arch-meson $pkgname build
+  ninja -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/src}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  pipewire &
+  trap "kill $!; wait" EXIT
+
+  meson test -C build --print-errorlogs
+)
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}