[arch-commits] Commit in (4 files)

[David Runge]

    Date: Friday, March 27, 2020 @ 17:53:25
  Author: dvzrv
Revision: 605017

Adding vim-ansible.

Added:
  vim-ansible/
  vim-ansible/repos/
  vim-ansible/trunk/
  vim-ansible/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: vim-ansible/trunk/PKGBUILD
===================================================================
--- vim-ansible/trunk/PKGBUILD	                        (rev 0)
+++ vim-ansible/trunk/PKGBUILD	2020-03-27 17:53:25 UTC (rev 605017)
@@ -0,0 +1,44 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=ansible-vim
+pkgname=vim-ansible
+pkgver=2.1
+pkgrel=2
+pkgdesc="A vim plugin for syntax highlighting Ansible's common filetypes "
+arch=('any')
+url="https://github.com/pearofducks/ansible-vim"
+license=('MIT')
+groups=('vim-plugins')
+depends=('python-jinja' 'vim')
+makedepends=('ansible' 'python')
+optdepends=('vim-ultisnips: for ansible snippets')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/pearofducks/${_name}/archive/${pkgver}.tar.gz")
+sha512sums=('630276ee0587bddea1ece4639e7bb744533dd212d3756f3071a188597e5091d4946536a9c6a4af013b6a3c0391a32d24809a0d10ab3d0b4e2fbaa7f4d89ac232')
+
+prepare() {
+  mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
+  cd "$pkgname-$pkgver"
+  # https://github.com/pearofducks/ansible-vim/issues/95
+  sed -e 's/jinja2/jinja/g' \
+      -i ftdetect/ansible.vim syntax/ansible.vim
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  python UltiSnips/generate.py --style 'dictionary' --sort
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  install -vDm 644 ftdetect/*.vim \
+    -t "${pkgdir}/usr/share/vim/vimfiles/ftdetect/"
+  install -vDm 644 ftplugin/*.vim \
+    -t "${pkgdir}/usr/share/vim/vimfiles/ftplugin/"
+  install -vDm 644 indent/*.vim -t "${pkgdir}/usr/share/vim/vimfiles/indent/"
+  install -vDm 644 syntax/ansible*.vim \
+    -t "${pkgdir}/usr/share/vim/vimfiles/syntax/"
+  install -vDm 644 ansible.snippets \
+    -t "${pkgdir}/usr/share/vim/vimfiles/snippets/"
+  install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}