[arch-commits] Commit in haskell-hasql/repos (2 files)

[Felix Yan]

    Date: Saturday, March 28, 2020 @ 15:41:26
  Author: felixonmars
Revision: 605239

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hasql/repos/community-staging-x86_64/
  haskell-hasql/repos/community-staging-x86_64/PKGBUILD
    (from rev 605238, haskell-hasql/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: haskell-hasql/repos/community-staging-x86_64/PKGBUILD (from rev 605238, haskell-hasql/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-28 15:41:26 UTC (rev 605239)
@@ -0,0 +1,60 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=hasql
+pkgname=haskell-hasql
+pkgver=1.4.2
+pkgrel=3
+pkgdesc="An efficient PostgreSQL driver and a flexible mapping API"
+url="https://github.com/nikita-volkov/hasql"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-base-prelude' 'haskell-bytestring-strict-builder'
+         'haskell-contravariant' 'haskell-contravariant-extras' 'haskell-dlist' 'haskell-hashable'
+         'haskell-hashtables' 'haskell-loch-th' 'haskell-placeholders' 'haskell-postgresql-binary'
+         'haskell-postgresql-libpq' 'haskell-profunctors' 'haskell-text-builder' 'haskell-vector')
+makedepends=('ghc' 'haskell-bug' 'haskell-tasty' 'haskell-tasty-quickcheck' 'haskell-tasty-hunit'
+             'haskell-quickcheck-instances' 'haskell-quickcheck' 'haskell-rebase' 'haskell-rerebase')
+checkdepends=('postgresql' 'pifpaf')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('74052de895ff78df41b634a558ac88c60702127f332410e9cc0abfdd48a1857eacef91770700f142490fbd4180d49c45277ec8e8b7a3740ac7facace2a1a7764')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/import Prelude as Exports/import Prelude as Exports hiding (mapLeft)/' tasty/Main/Prelude.hs
+
+    # Do not use default postgres port
+    sed -i 's/5432/9824/' tasty/Main/*.hs threads-test/*.hs profiling/*.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+
+    eval $(pifpaf run postgresql --host 127.0.0.1)
+    createuser -s postgres
+    runhaskell Setup test
+    pifpaf_stop
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}