[arch-commits] Commit in libfido2/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Levente Polyak]

    Date: Saturday, March 28, 2020 @ 19:00:06
  Author: anthraxx
Revision: 378628

archrelease: copy trunk to staging-x86_64

Added:
  libfido2/repos/staging-x86_64/
  libfido2/repos/staging-x86_64/PKGBUILD
    (from rev 378627, libfido2/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: libfido2/repos/staging-x86_64/PKGBUILD (from rev 378627, libfido2/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-03-28 19:00:06 UTC (rev 378628)
@@ -0,0 +1,42 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Karol Babioch <karol at babioch.de>
+
+pkgname=libfido2
+pkgver=1.3.1
+pkgrel=2
+pkgdesc='Library functionality for FIDO 2.0, including communication with a device over USB'
+url='https://developers.yubico.com/libfido2/'
+arch=('x86_64')
+license=('BSD')
+depends=('glibc' 'openssl' 'libcbor' 'libcbor.so' 'hidapi' 'systemd-libs'  'libudev.so')
+makedepends=('cmake')
+provides=('libfido2.so')
+source=(https://developers.yubico.com/libfido2/Releases/libfido2-${pkgver}.tar.gz{,.sig})
+sha256sums=('ba35e22016b60c1e4be66dff3cd6a60c1fe4bfa0d91ec0b89ca9da25ebeaaf41'
+            'SKIP')
+b2sums=('f69a04fc69c46b688d83afe9d72b2fb1860ac00a09665d55e25293595520e95d45486ecc5355c479bc8bc06dbe6ed4fd469c511f5bf5f341a0ec86cb099fce28'
+        'SKIP')
+validpgpkeys=(
+  'EE90AE0D19774C8386628FAAB428949EF7914718' # pedro martelletto <pedro at yubico.com>
+  '1D7308B0055F5AEF36944A8F27A9C24D9588EA0F' # Aveen Ismail <aveen.ismail at yubico.com>
+)
+
+build() {
+  mkdir -p ${pkgname}-${pkgver}/build
+  cd ${pkgname}-${pkgver}/build
+  cmake .. \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_C_FLAGS="${CFLAGS} ${CPPFLAGS}"
+  make VERBOSE=1
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make -C build DESTDIR="${pkgdir}" install
+  install -Dm 644 NEWS README.adoc -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: