[arch-commits] Commit in haskell-data-serializer/repos (2 files)

[Felix Yan]

    Date: Sunday, March 29, 2020 @ 17:41:35
  Author: felixonmars
Revision: 606211

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-data-serializer/repos/community-staging-x86_64/
  haskell-data-serializer/repos/community-staging-x86_64/PKGBUILD
    (from rev 606210, haskell-data-serializer/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-data-serializer/repos/community-staging-x86_64/PKGBUILD (from rev 606210, haskell-data-serializer/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-29 17:41:35 UTC (rev 606211)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=data-serializer
+pkgname=haskell-data-serializer
+pkgver=0.3.4.1
+pkgrel=24
+pkgdesc="Common API for serialization libraries"
+url="https://github.com/mvv/data-serializer"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-cereal' 'haskell-data-endian' 'haskell-parsers' 'haskell-split')
+makedepends=('ghc' 'haskell-tasty' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a19693bb24bf5e51197d3d3c34bc398ce50eae7ec52f651acf6aad1e6c8e2a56c57dd07aaeb16cd729a7401f986a3baf4b166a47f87438a667ba0ab0b9023d53')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}