[arch-commits] Commit in haskell-path-io/repos (2 files)

[Felix Yan]

    Date: Sunday, March 29, 2020 @ 17:45:48
  Author: felixonmars
Revision: 606221

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-path-io/repos/community-staging-x86_64/
  haskell-path-io/repos/community-staging-x86_64/PKGBUILD
    (from rev 606220, haskell-path-io/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-path-io/repos/community-staging-x86_64/PKGBUILD (from rev 606220, haskell-path-io/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-29 17:45:48 UTC (rev 606221)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Nagy <danielnagy at gmx de>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+
+_hkgname=path-io
+pkgname=haskell-path-io
+pkgver=1.6.0
+pkgrel=14
+pkgdesc="Interface to ‘directory’ package for users of ‘path’"
+url="https://github.com/mrkkrp/path-io"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-dlist' 'haskell-exceptions' 'haskell-path' 'haskell-temporary'
+         'haskell-unix-compat')
+makedepends=('ghc' 'haskell-hspec')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-${pkgver}.tar.gz")
+sha512sums=('dcafbbfe1531d7b00a9df751c093e6affdefafe7589c0243530579b9f5733ef1357b1085cfd88bf53ff9794accddbc789b927a199f4c4a2b7778268cf1719477')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  sed -i -e 's/< *0.7/<1/' $_hkgname.cabal
+}
+
+build() {
+  cd "$srcdir/$_hkgname-$pkgver"
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-dev
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+  
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.md
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE.md
+}