[arch-commits] Commit in (4 files)

[Jonas Witschel]

    Date: Sunday, March 29, 2020 @ 23:18:03
  Author: diabonas
Revision: 606640

Initial import of python-matrix-nio

Added:
  python-matrix-nio/
  python-matrix-nio/repos/
  python-matrix-nio/trunk/
  python-matrix-nio/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: python-matrix-nio/trunk/PKGBUILD
===================================================================
--- python-matrix-nio/trunk/PKGBUILD	                        (rev 0)
+++ python-matrix-nio/trunk/PKGBUILD	2020-03-29 23:18:03 UTC (rev 606640)
@@ -0,0 +1,39 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+pkgname=python-matrix-nio
+pkgver=0.10.0
+_tag=55b4a01732def2865576335ab8ec867ac26c81e4 # git show-ref "$pkgver"
+pkgrel=1
+pkgdesc='Python Matrix client library, designed according to sans I/O principles'
+arch=('any')
+url='https://github.com/poljar/matrix-nio'
+license=('ISC')
+depends=('python-aiofiles' 'python-aiohttp' 'python-atomicwrites' 'python-attrs' 'python-cachetools'
+         'python-future' 'python-h11' 'python-h2' 'python-jsonschema' 'python-logbook' 'python-olm'
+         'python-peewee' 'python-pycryptodome' 'python-unpaddedbase64')
+makedepends=('git')
+checkdepends=('python-aioresponses' 'python-faker' 'python-hypothesis' 
+              'python-pytest' 'python-pytest-aiohttp' 'python-pytest-benchmark')
+source=("git+$url.git?signed#tag=$_tag")
+sha512sums=('SKIP')
+validpgpkeys=('689A3B5BC6560AB4C99A2A0581314DA807EF4E22') # Damir Jelić (poljar) <poljar at termina.org.uk>
+
+pkgver() {
+	cd "${pkgname#python-}"
+	git describe | sed 's/\([^-]*-\)g/r\1/;s/-/./g'
+}
+
+build() {
+	cd "${pkgname#python-}"
+	python setup.py build
+}
+
+check() {
+	cd "${pkgname#python-}"
+	python -m pytest
+}
+
+package() {
+	cd "${pkgname#python-}"
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+	install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}