[arch-commits] Commit in shiboken2/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Antonio Rojas arojas at archlinux.org
Tue Mar 31 11:30:44 UTC 2020


    Date: Tuesday, March 31, 2020 @ 11:30:43
  Author: arojas
Revision: 378904

archrelease: copy trunk to testing-x86_64

Added:
  shiboken2/repos/testing-x86_64/
  shiboken2/repos/testing-x86_64/PKGBUILD
    (from rev 378903, shiboken2/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: shiboken2/repos/testing-x86_64/PKGBUILD (from rev 378903, shiboken2/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-03-31 11:30:43 UTC (rev 378904)
@@ -0,0 +1,48 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=shiboken2
+pkgname=(shiboken2 python-shiboken2)
+_qtver=5.14.2
+_clangver=9.0.1
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL2 LGPL)
+pkgdesc='Generates bindings for C++ libraries using CPython source code'
+makedepends=(clang llvm cmake libxslt qt5-xmlpatterns python-sphinx)
+_pkgfqn=pyside-setup-opensource-src-${_qtver}
+source=("https://download.qt.io/official_releases/QtForPython/pyside2/PySide2-$pkgver-src/${_pkgfqn}.tar.xz")
+sha256sums=('7c7af33792de57255dbdc165c808e1f03a2520295c5922d9897aca8ad1be92b3')
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../${_pkgfqn}/sources/shiboken2 \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_TESTS=OFF \
+    -DUSE_PYTHON_VERSION=3
+  make
+}
+
+package_shiboken2() {
+  depends=(clang=$_clangver llvm libxslt qt5-xmlpatterns)
+
+  cd build
+  make DESTDIR="$pkgdir" install
+# Provided in python-shiboken2
+  rm -r "$pkgdir"/usr/lib/{python*,libshiboken*}
+}
+
+package_python-shiboken2() {
+  depends=(python)
+
+  cd build
+  make DESTDIR="$pkgdir" install
+# Provided in shiboken2
+  rm -r "$pkgdir"/usr/{bin,include,lib/{cmake,pkgconfig}}
+}



More information about the arch-commits mailing list