[arch-commits] Commit in haskell-pcre-light/repos (2 files)

[Felix Yan]

    Date: Tuesday, March 31, 2020 @ 15:21:38
  Author: felixonmars
Revision: 608114

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-pcre-light/repos/community-staging-x86_64/
  haskell-pcre-light/repos/community-staging-x86_64/PKGBUILD
    (from rev 608113, haskell-pcre-light/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-pcre-light/repos/community-staging-x86_64/PKGBUILD (from rev 608113, haskell-pcre-light/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-31 15:21:38 UTC (rev 608114)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=pcre-light
+pkgname=haskell-pcre-light
+pkgver=0.4.1.0
+pkgrel=26
+pkgdesc="Portable regex library for Perl 5 compatible regular expressions"
+url="https://github.com/Daniel-Diaz/pcre-light"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'pcre')
+makedepends=('ghc' 'haskell-hunit')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('491d9581e4c29d1a5a3b161210b83abbc135c2d0ee4018481f4101f91c95e93d7acf0764cb464a9ffe84bed9bf8fb400f4c68441ae1be03c0aa182a9be26dc39')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-old_base -fuse-pkg-config
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}