[arch-commits] Commit in haskell-hspec-core/repos (2 files)

[Felix Yan]

    Date: Tuesday, March 31, 2020 @ 21:41:26
  Author: felixonmars
Revision: 608368

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hspec-core/repos/community-staging-x86_64/
  haskell-hspec-core/repos/community-staging-x86_64/PKGBUILD
    (from rev 608367, haskell-hspec-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-hspec-core/repos/community-staging-x86_64/PKGBUILD (from rev 608367, haskell-hspec-core/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-31 21:41:26 UTC (rev 608368)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hspec-core
+pkgname=haskell-hspec-core
+pkgver=2.7.1
+pkgrel=37
+pkgdesc="A Testing Framework for Haskell"
+url="http://hspec.github.io/"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-call-stack' 'haskell-clock'
+         'haskell-hspec-expectations' 'haskell-hunit' 'haskell-quickcheck' 'haskell-quickcheck-io'
+         'haskell-random' 'haskell-setenv' 'haskell-tf-random')
+makedepends=('ghc' 'haskell-hspec-meta' 'haskell-silently' 'haskell-temporary')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('5ab0925566c3b6f05480bd4e464ca32e0a212b4b4ff439d02b3df5b75b23b45ca0c63bab8398ebeeedce0ba30bb653b1ea85df2b7e6e3a058cb4413dc1c53ee2')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # https://github.com/hspec/hspec/issues/432
+    runhaskell Setup test || :
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}