[arch-commits] Commit in haskell-generic-random/repos (2 files)

[Felix Yan]

    Date: Tuesday, March 31, 2020 @ 22:18:48
  Author: felixonmars
Revision: 608446

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-generic-random/repos/community-staging-x86_64/
  haskell-generic-random/repos/community-staging-x86_64/PKGBUILD
    (from rev 608445, haskell-generic-random/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-generic-random/repos/community-staging-x86_64/PKGBUILD (from rev 608445, haskell-generic-random/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-03-31 22:18:48 UTC (rev 608446)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=generic-random
+pkgname=haskell-generic-random
+pkgver=1.3.0.1
+pkgrel=2
+pkgdesc="Generic random generators for QuickCheck"
+url="https://github.com/lysxia/generic-random"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck')
+makedepends=('ghc' 'haskell-inspection-testing')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('d936f6b2cab03275e37f07664602a2ab0037efa1a0b76682bd032141390f14ad70c263fed64bf9105a71b098c67d7ce06dccb78ec1d8cc59fc9ffd1e05fde8b8')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}