[arch-commits] Commit in json-c/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Christian Hesse]

    Date: Tuesday, May 5, 2020 @ 09:23:59
  Author: eworm
Revision: 382273

archrelease: copy trunk to testing-x86_64

Added:
  json-c/repos/testing-x86_64/
  json-c/repos/testing-x86_64/PKGBUILD
    (from rev 382272, json-c/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: json-c/repos/testing-x86_64/PKGBUILD (from rev 382272, json-c/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-05-05 09:23:59 UTC (rev 382273)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Geoffroy Carrier <geoffroy.carrier at koon.fr>
+# Contributor: congyiwu <congyiwu AT gmail DOT com>
+
+pkgname=json-c
+pkgver=0.14
+pkgrel=2
+pkgdesc="A JSON implementation in C"
+url="https://github.com/json-c/json-c/wiki"
+license=(MIT)
+arch=(x86_64)
+depends=(glibc)
+makedepends=(git cmake)
+provides=(libjson-c.so)
+_commit=bae2f10c436eaf0d95746cbc5f1c1f0ecb866a8e  # tags/json-c-0.14-20200419^0
+source=("git+https://github.com/json-c/json-c#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd json-c
+  local tag="$(git describe --tags --abbrev=0)"
+  local ver="$(git describe --tags)"
+  echo "${tag%-*}${ver#$tag}" | sed 's/^json-c-//;s/-/+/g'
+}
+
+prepare() {
+  cd json-c
+
+  # Detect broken RDRAND during initialization
+  git cherry-pick -n 4d36b0287d3ab0912ba8a4790340ca099960b2b0
+}
+
+build() {
+  cmake -Hjson-c -Bbuild \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+    -DENABLE_THREADING=ON \
+    -DENABLE_RDRAND=ON
+  cmake --build build
+}
+
+check() {
+  cmake --build build --target test
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --build build --target install
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 json-c/COPYING
+}
+
+# vim:set sw=2 et: