[arch-commits] Commit in radare2/repos (2 files)

[Levente Polyak]

    Date: Friday, May 8, 2020 @ 21:33:02
  Author: anthraxx
Revision: 625783

archrelease: copy trunk to community-staging-x86_64

Added:
  radare2/repos/community-staging-x86_64/
  radare2/repos/community-staging-x86_64/PKGBUILD
    (from rev 625782, radare2/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: radare2/repos/community-staging-x86_64/PKGBUILD (from rev 625782, radare2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-05-08 21:33:02 UTC (rev 625783)
@@ -0,0 +1,44 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Guillermo Ramos <0xwille at gmail dot com>
+
+pkgname=radare2
+pkgver=4.4.0
+pkgrel=1
+pkgdesc='Open-source tools to disasm, debug, analyze and manipulate binary files'
+url='https://radare.org'
+arch=('x86_64')
+license=('GPL3' 'LGPL3')
+depends=('sh' 'capstone' 'libcapstone.so' 'openssl' 'libzip' 'zlib'
+         'lz4' 'xxhash' 'libxxhash.so' 'file' 'libuv')
+makedepends=('meson')
+optdepends=('r2ghidra-dec: ghidra decompiler plugin')
+options=('!emptydirs')
+source=(https://github.com/radare/radare2/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('6208d97f8333e72dfd04cccdb0234b60fb8979ca559b92532bf7e47d402f91e0c54678a83e6bafee65666fb7d6008b44b961600f24f9b3275cb2eec32490eaa5')
+b2sums=('1a1a4ce97dde4b8985cbe95bb889bfdef8f9d64e2c2257030fda523b1a1aced4e6681bc0f7b14d1a3f25fbce355f2062f0edc33ab396bef98792d29d1f708a11')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  touch libr/config.mk
+  arch-meson build \
+    -D use_sys_capstone=true \
+    -D use_sys_magic=true \
+    -D use_sys_zip=true \
+    -D use_sys_zlib=true \
+    -D use_sys_lz4=true \
+    -D use_sys_xxhash=true \
+    -D use_sys_openssl=true \
+    -D use_libuv=true \
+    -D use_webui=true
+  ninja -C build
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  DESTDIR="${pkgdir}" ninja -C build install
+  cp -r doc/* "${pkgdir}/usr/share/doc/radare2"
+  ln -s /usr/bin/radare2 "${pkgdir}/usr/bin/r2"
+  ln -s /usr/share/man/man1/radare2.1.gz "${pkgdir}/usr/share/man/man1/r2.1.gz"
+}
+
+# vim: ts=2 sw=2 et: