[arch-commits] Commit in (5 files)

Alexander Rødseth arodseth at archlinux.org
Sat May 9 16:20:55 UTC 2020


    Date: Saturday, May 9, 2020 @ 16:20:47
  Author: arodseth
Revision: 626000

Add global from AUR (129 votes)

Added:
  global/
  global/repos/
  global/repos/community-x86_64/
  global/trunk/
  global/trunk/PKGBUILD

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Added: global/trunk/PKGBUILD
===================================================================
--- global/trunk/PKGBUILD	                        (rev 0)
+++ global/trunk/PKGBUILD	2020-05-09 16:20:47 UTC (rev 626000)
@@ -0,0 +1,63 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Fredy García <frealgagu at gmail dot com>
+# Contributor: Randy Ramos <rramos1295 at gmail dot com>
+# Contributor: Peter Vasil <mail at petervasil.net>
+# Contributor: Lucas De Marchi <lucas.de.marchi at gmail.com>
+# Contributor: Matthias Meulien <orontee at gmail.com>
+
+pkgname=global
+pkgver=6.6.4
+pkgrel=1
+pkgdesc='Source code tag system'
+arch=(x86_64)
+url='https://www.gnu.org/software/global/'
+license=(GPL)
+depends=(bash libltdl perl python sqlite)
+optdepends=(ctags emacs idutils python-pygments vim)
+options=(!emptydirs !libtool)
+source=("https://ftp.gnu.org/pub/gnu/$pkgname/$pkgname-$pkgver.tar.gz")
+sha256sums=('987e8cb956c53f8ebe4453b778a8fde2037b982613aba7f3e8e74bcd05312594')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+
+  sed -i 's/\.la/.so/g' gtags.conf.in
+
+  # Rename lid to lid-idutils to avoid a name collision with idutils from AUR
+  sed -i 's/usable("lid")/usable("lid-idutils")/g' "$pkgname/$pkgname.c"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+
+  autoreconf -fi
+  ./configure \
+    --prefix=/usr \
+    --with-exuberant-ctags=/usr/bin/ctags \
+    --with-sqlite3
+  make
+}
+
+check() {
+  make -C "$pkgname-$pkgver" -k check
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir" install
+
+  # Package the emacs script
+  install -d "$pkgdir/usr/share/emacs/site-lisp"
+  mv "$pkgdir/usr/share/gtags/gtags.el" \
+    "$pkgdir/usr/share/emacs/site-lisp/gtags.el"
+
+  # Package the vim scripts
+  install -d "$pkgdir/usr/share/vim/vimfiles/plugin"
+  mv "$pkgdir/usr/share/gtags/gtags.vim" \
+    "$pkgdir/usr/share/vim/vimfiles/plugin/gtags.vim"
+  mv "$pkgdir/usr/share/gtags/gtags-cscope.vim" \
+    "$pkgdir/usr/share/vim/vimfiles/plugin/gtags-cscope.vim"
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list