[arch-commits] Commit in dbus-broker/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Monday, May 11, 2020 @ 21:07:52
  Author: heftig
Revision: 383254

archrelease: copy trunk to extra-x86_64

Added:
  dbus-broker/repos/extra-x86_64/PKGBUILD
    (from rev 383253, dbus-broker/trunk/PKGBUILD)
Deleted:
  dbus-broker/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  119 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 60 insertions(+), 59 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-05-11 21:06:55 UTC (rev 383253)
+++ PKGBUILD	2020-05-11 21:07:52 UTC (rev 383254)
@@ -1,59 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Contributor: David Herrmann <dh.herrmann at gmail.com>
-
-pkgname=dbus-broker
-pkgver=22
-pkgrel=2
-pkgdesc="Linux D-Bus Message Broker"
-url="https://github.com/bus1/dbus-broker/wiki"
-arch=(x86_64)
-license=(Apache)
-depends=(systemd-libs expat audit)
-makedepends=(git meson systemd python-docutils)
-_commit=6d55eb8aa772ed7d69d6b98ab007f2308df5a613  # tags/v22^0
-source=("git+https://github.com/bus1/dbus-broker#commit=$_commit"
-        git+https://github.com/c-util/c-{rbtree,list,dvar,utf8,shquote,ini,stdaux})
-sha256sums=('SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/^v//;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-
-  git submodule init
-
-  local sm
-  for sm in c-{rbtree,list,dvar,utf8,shquote,ini,stdaux}; do
-    git submodule set-url subprojects/$sm "$srcdir/$sm"
-  done
-
-  git submodule update
-}
-
-build() {
-  arch-meson $pkgname build \
-    -D audit=true \
-    -D docs=true \
-    -D system-console-users=gdm,sddm,lightdm,lxdm
-  ninja -C build
-}
-
-check() {
-  meson test -C build --print-errorlogs
-}
-
-package() {
-  DESTDIR="$pkgdir" meson install -C build
-}
-
-# vim:set sw=2 et:

Copied: dbus-broker/repos/extra-x86_64/PKGBUILD (from rev 383253, dbus-broker/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-05-11 21:07:52 UTC (rev 383254)
@@ -0,0 +1,60 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: David Herrmann <dh.herrmann at gmail.com>
+
+pkgname=dbus-broker
+pkgver=23
+pkgrel=1
+pkgdesc="Linux D-Bus Message Broker"
+url="https://github.com/bus1/dbus-broker/wiki"
+arch=(x86_64)
+license=(Apache)
+depends=(systemd-libs expat audit)
+makedepends=(git meson systemd python-docutils)
+_commit=63562655d3dc48460e8b06c540b8a98204cd46c5  # tags/v23^0
+source=("git+https://github.com/bus1/dbus-broker#commit=$_commit"
+        git+https://github.com/c-util/c-{rbtree,list,dvar,utf8,shquote,ini,stdaux})
+sha256sums=('SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+
+  local sm
+  for sm in c-{rbtree,list,dvar,utf8,shquote,ini,stdaux}; do
+    git submodule set-url subprojects/$sm "$srcdir/$sm"
+  done
+
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D audit=true \
+    -D docs=true \
+    -D linux-4-17=true \
+    -D system-console-users=gdm,sddm,lightdm,lxdm
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set sw=2 et: