[arch-commits] Commit in pegtl/repos (2 files)
Levente Polyak
anthraxx at archlinux.org
Fri May 15 19:10:00 UTC 2020
Date: Friday, May 15, 2020 @ 19:10:00
Author: anthraxx
Revision: 628080
archrelease: copy trunk to community-testing-any
Added:
pegtl/repos/community-testing-any/
pegtl/repos/community-testing-any/PKGBUILD
(from rev 628079, pegtl/trunk/PKGBUILD)
----------+
PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 45 insertions(+)
Copied: pegtl/repos/community-testing-any/PKGBUILD (from rev 628079, pegtl/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD (rev 0)
+++ community-testing-any/PKGBUILD 2020-05-15 19:10:00 UTC (rev 628080)
@@ -0,0 +1,45 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=pegtl
+_gitcommit=47e878ad4fd72c91253c9d47b6f17e001ca2dfcf
+pkgver=2.8.3
+pkgrel=1
+pkgdesc='Parsing Expression Grammar Template Library'
+url='https://github.com/taocpp/PEGTL'
+arch=('any')
+license=('MIT')
+makedepends=('git' 'cmake')
+source=(${pkgname}::"git+https://github.com/taocpp/PEGTL#commit=${_gitcommit}?signed")
+sha512sums=('SKIP')
+validpgpkeys=('3AC06334B62566C11A5912FB014C496DEC39EB21') # Daniel Frey <d.frey at gmx.de>
+
+pkgver() {
+ cd ${pkgname}
+ git describe --tags --always| sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+ cd ${pkgname}
+ cmake -B build \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=None \
+ -DPEGTL_INSTALL_DOC_DIR=share/doc/${pkgname} \
+ -DPEGTL_INSTALL_CMAKE_DIR=lib/cmake/${pkgname} \
+ -DPEGTL_BUILD_EXAMPLES=OFF \
+ -DPEGTL_BUILD_TESTS=ON
+ make -C build VERRBOSE=1
+}
+
+check() {
+ cd ${pkgname}/build
+ ctest
+}
+
+package() {
+ cd ${pkgname}
+ make -C build DESTDIR="${pkgdir}" install
+ install -Dpm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+ install -Dpm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list