[arch-commits] Commit in libvpx/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Saturday, May 16, 2020 @ 11:20:05
  Author: felixonmars
Revision: 384284

archrelease: copy trunk to staging-x86_64

Added:
  libvpx/repos/staging-x86_64/
  libvpx/repos/staging-x86_64/PKGBUILD
    (from rev 384283, libvpx/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: libvpx/repos/staging-x86_64/PKGBUILD (from rev 384283, libvpx/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-05-16 11:20:05 UTC (rev 384284)
@@ -0,0 +1,51 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+
+pkgname=libvpx
+pkgver=1.8.2
+pkgrel=2
+pkgdesc='VP8 and VP9 codec'
+arch=(x86_64)
+url=https://www.webmproject.org/
+license=(BSD)
+makedepends=(
+  git
+  nasm
+)
+provides=(libvpx.so)
+source=(git+https://chromium.googlesource.com/webm/libvpx#tag=7ec7a33a081aeeb53fed1a8d87e4cbd189152527)
+sha256sums=(SKIP)
+
+pkgver() {
+  cd libvpx
+
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cd libvpx
+
+  ./configure \
+    --prefix=/usr \
+    --disable-install-docs \
+    --disable-install-srcs \
+    --enable-pic \
+    --enable-postproc \
+    --enable-runtime-cpu-detect \
+    --enable-shared \
+    --enable-vp8 \
+    --enable-vp9 \
+    --enable-vp9-highbitdepth \
+    --enable-vp9-temporal-denoising
+  make
+}
+
+package() {
+  cd libvpx
+
+  make DIST_DIR="${pkgdir}"/usr install
+  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/libvpx/
+}
+
+# vim: ts=2 sw=2 et: