[arch-commits] Commit in mtr/repos (3 files)
Evangelos Foutras
foutrelis at archlinux.org
Sat May 16 11:43:05 UTC 2020
Date: Saturday, May 16, 2020 @ 11:43:05
Author: foutrelis
Revision: 384332
archrelease: copy trunk to staging-x86_64
Added:
mtr/repos/staging-x86_64/
mtr/repos/staging-x86_64/PKGBUILD
(from rev 384331, mtr/trunk/PKGBUILD)
mtr/repos/staging-x86_64/mtr.install
(from rev 384331, mtr/trunk/mtr.install)
-------------+
PKGBUILD | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
mtr.install | 9 ++++++++
2 files changed, 69 insertions(+)
Copied: mtr/repos/staging-x86_64/PKGBUILD (from rev 384331, mtr/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2020-05-16 11:43:05 UTC (rev 384332)
@@ -0,0 +1,60 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+
+pkgbase=mtr
+pkgname=('mtr' 'mtr-gtk')
+pkgver=0.93
+pkgrel=3
+pkgdesc='Combines the functionality of traceroute and ping into one tool'
+url='https://www.bitwizard.nl/mtr/'
+arch=('x86_64')
+license=('GPL2')
+makedepends=('ncurses' 'gtk2' 'libcap')
+install=mtr.install
+source=(https://github.com/traviscross/mtr/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('865c394d8dfa234c472832dc205ddc9ec3cf0552475f565782fd4f4e878251c03f1473e2d28d6799e59da4fcb33c5355049f1e6f02e8610c6bbf681ffb78f53e')
+
+prepare() {
+ (cd ${pkgbase}-${pkgver}
+ echo "${pkgver}" > .tarball-version
+ autoreconf -fiv
+ )
+ cp -ra ${pkgbase}-${pkgver}{,-cli}
+}
+
+build() {
+ (cd ${pkgbase}-${pkgver}-cli
+ ./configure \
+ --prefix=/usr \
+ --without-gtk \
+ --sbindir=/usr/bin
+ make
+ )
+ (cd ${pkgbase}-${pkgver}
+ ./configure \
+ --prefix=/usr \
+ --sbindir=/usr/bin
+ make
+ )
+}
+
+package_mtr() {
+ pkgdesc='Combines the functionality of traceroute and ping into one tool (CLI version)'
+ depends=('ncurses' 'libcap')
+ optdepends=('bash-completion: bash completion support')
+ cd ${pkgbase}-${pkgver}-cli
+ make DESTDIR="${pkgdir}" install
+}
+
+package_mtr-gtk() {
+ pkgdesc='Combines the functionality of traceroute and ping into one tool (GTK version)'
+ depends=('ncurses' 'libcap' 'gtk2')
+ optdepends=('bash-completion: bash completion support')
+ conflicts=('mtr')
+ provides=("mtr=${pkgver}")
+ cd ${pkgbase}-${pkgver}
+ make DESTDIR="${pkgdir}" install
+}
+
+# vim: ts=2 sw=2 et:
Copied: mtr/repos/staging-x86_64/mtr.install (from rev 384331, mtr/trunk/mtr.install)
===================================================================
--- staging-x86_64/mtr.install (rev 0)
+++ staging-x86_64/mtr.install 2020-05-16 11:43:05 UTC (rev 384332)
@@ -0,0 +1,9 @@
+post_install() {
+ setcap cap_net_bind_service,cap_net_raw+ep usr/bin/mtr-packet
+}
+
+post_upgrade() {
+ post_install
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list