[arch-commits] Commit in fping/repos (3 files)

Evangelos Foutras foutrelis at archlinux.org
Sat May 16 20:50:27 UTC 2020


    Date: Saturday, May 16, 2020 @ 20:50:26
  Author: foutrelis
Revision: 384830

archrelease: copy trunk to staging-x86_64

Added:
  fping/repos/staging-x86_64/
  fping/repos/staging-x86_64/PKGBUILD
    (from rev 384829, fping/trunk/PKGBUILD)
  fping/repos/staging-x86_64/fping.install
    (from rev 384829, fping/trunk/fping.install)

---------------+
 PKGBUILD      |   37 +++++++++++++++++++++++++++++++++++++
 fping.install |    9 +++++++++
 2 files changed, 46 insertions(+)

Copied: fping/repos/staging-x86_64/PKGBUILD (from rev 384829, fping/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-05-16 20:50:26 UTC (rev 384830)
@@ -0,0 +1,37 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Tom Newsom <Jeepster at gmx.co.uk>
+
+pkgname=fping
+pkgver=4.2
+pkgrel=2
+pkgdesc='Utility to ping multiple hosts at once'
+url='https://www.fping.org/'
+arch=('x86_64')
+license=('custom')
+depends=('glibc')
+install=${pkgname}.install
+source=(https://www.fping.org/dist/${pkgname}-${pkgver}.tar.gz{,.asc})
+sha512sums=('2bab34dae539d942eb5e436802e6f74d57c04aa4b782f9adbd6c27830209fdb47707131f20ed966012bcec3d253c9bb3df9033a60b55bfe560af6bb1f572ee8a'
+            'SKIP')
+validpgpkeys=('8D1E89B8FBA920A5A609F2615A11A22BC5A1F734') # David Schweikert <david at schweikert.ch>
+
+build() {
+  cd ${pkgname}-${pkgver}
+  CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
+  ./configure \
+    --prefix=/usr \
+    --sbindir=/usr/bin \
+    --mandir=/usr/share/man \
+    --enable-ipv4 \
+    --enable-ipv6
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:

Copied: fping/repos/staging-x86_64/fping.install (from rev 384829, fping/trunk/fping.install)
===================================================================
--- staging-x86_64/fping.install	                        (rev 0)
+++ staging-x86_64/fping.install	2020-05-16 20:50:26 UTC (rev 384830)
@@ -0,0 +1,9 @@
+post_install() {
+  setcap cap_net_raw=ep usr/bin/fping  2>/dev/null || chmod +s usr/bin/fping
+}
+
+post_upgrade() {
+  post_install "$1"
+}
+
+# vim:set ts=2 sw=2 et:



More information about the arch-commits mailing list