[arch-commits] Commit in liboauth/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Tuesday, May 19, 2020 @ 07:55:54
  Author: felixonmars
Revision: 386071

archrelease: copy trunk to staging-x86_64

Added:
  liboauth/repos/staging-x86_64/
  liboauth/repos/staging-x86_64/PKGBUILD
    (from rev 386070, liboauth/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: liboauth/repos/staging-x86_64/PKGBUILD (from rev 386070, liboauth/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-05-19 07:55:54 UTC (rev 386071)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Kaiting Chen <kaitocracy at gmail.com>
+# Contributor: Martin Häger <martin.haeger at gmail.com>
+
+pkgname=liboauth
+pkgver=1.0.3+14+g186fb14
+pkgrel=2
+pkgdesc="C library implementing OAuth Core RFC 5849"
+url="https://github.com/x42/liboauth"
+arch=(x86_64)
+license=(MIT)
+depends=(curl nss)
+makedepends=(git)
+_commit=186fb14843c1bc98b70ece02c74b5696b3de9ce7  # master
+source=("git+$url#commit=$_commit")
+sha256sums=('SKIP')
+
+prepare() {
+  cd $pkgname
+  autoreconf -fvi
+}
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --disable-static --enable-nss
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING.MIT "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}