[arch-commits] Commit in dleyna-core/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Evangelos Foutras
foutrelis at archlinux.org
Tue May 19 08:11:41 UTC 2020
Date: Tuesday, May 19, 2020 @ 08:11:40
Author: foutrelis
Revision: 386184
archrelease: copy trunk to staging-x86_64
Added:
dleyna-core/repos/staging-x86_64/
dleyna-core/repos/staging-x86_64/PKGBUILD
(from rev 386183, dleyna-core/trunk/PKGBUILD)
----------+
PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 42 insertions(+)
Copied: dleyna-core/repos/staging-x86_64/PKGBUILD (from rev 386183, dleyna-core/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2020-05-19 08:11:40 UTC (rev 386184)
@@ -0,0 +1,42 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=dleyna-core
+pkgver=0.6.0+2+g1c6853f
+pkgrel=2
+pkgdesc="Library of utility functions that are used by the higher level dLeyna"
+arch=(x86_64)
+url="https://01.org/dleyna"
+license=(LGPL2.1)
+depends=(gupnp)
+makedepends=(git)
+_commit=1c6853f5bc697dc0a8774fd70dbc915c4dbe7c5b # master
+source=("git+https://github.com/01org/dleyna-core#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+ --disable-static
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+check() {
+ cd $pkgname
+ make check
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list