[arch-commits] Commit in libasyncns/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Tuesday, May 19, 2020 @ 08:28:01
  Author: felixonmars
Revision: 386316

archrelease: copy trunk to staging-x86_64

Added:
  libasyncns/repos/staging-x86_64/
  libasyncns/repos/staging-x86_64/PKGBUILD
    (from rev 386315, libasyncns/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: libasyncns/repos/staging-x86_64/PKGBUILD (from rev 386315, libasyncns/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-05-19 08:28:01 UTC (rev 386316)
@@ -0,0 +1,40 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Corrado Primier <bardo at aur.archlinux.org>
+# Contributor: Eric Belanger <belanger at astro.umontreal.ca>
+# Contributor: William Rea <sillywilly at gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=libasyncns
+pkgver=0.8+3+g68cd5af
+pkgrel=3
+pkgdesc="A C library for executing name service queries asynchronously"
+arch=(x86_64)
+url="http://0pointer.de/lennart/projects/libasyncns"
+license=(LGPL)
+depends=(glibc)
+makedepends=(git lynx)
+_commit=68cd5aff1467638c086f1bedcc750e34917168e4
+source=("git://git.0pointer.de/libasyncns.git#commit=$_commit")
+md5sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./bootstrap.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}